시계 만들기

Step 1: 워크시트에 시계 만들기

그래도 명색이 100회 강좌인데 그냥 넘어가기는 뭐하고 해서 워크시트 상에 시계를 하나 만들어 보도록 하겠습니다. 오래 전 강좌에서 소개해 드린 재귀적 호출구조를 사용한 것으로 논리 자체는 아주 간단합니다.

일정한 시간마다 특정한 작업을 반복해서 실행하고자 할 때 OnTime Method를 사용합니다. Start 버튼을 누르세요(시계를 멈추시려면 Stop 버튼을…).

매초마다 값이 갱신되는, 즉 시계가 워크시트 상에 만들어 졌지요? 코드는 엄청 간단합니다. 겨우 넉 줄입니다. ^^

Dim datTime As Date
'//다른 프로시저에서도 사용하기 위해 외부 변수로 선언하였습니다.

Sub MakeTimer()
    datTime = Now + TimeSerial(0, 0, 1)
    '//1초마다 시계를 Update 하기 위해 Now + TimeSerial(0,0,1)을 해 줍니다.

    Beep
    Range("start") = Format(Now, "hh:mm:ss AM/PM")
    Application.OnTime datTime, "MakeTimer"
    '//Application.OnTime datTime에서 datTime 변수에는 현재 시간 +1초라는 시간값이
    '//들어 있으니까 매초마다 MakeTimer, 즉 자기자신을 호출하게 됩니다.
    '//바로 재귀적 호출이지요.
    '//여기서 Beep는 Beep, 즉 삑삑 거리는 소리가 나도록 하는 명령입니다.

End Sub

Sub StopTimer()
'//위의 MakeTimer 프로시저는 재귀적 호출구조를 가진 것으로 외부에서 다른 특별한
'//명령을 주지 않는 이상 무한 루핑을 합니다. 따라서 프로시저를 종료하기 위한 장치를
'//마련해 두는 것입니다. Ctrl + Pause 키를 눌러도 종료됩니다.

    On Error Resume Next
    Application.OnTime datTime, "MakeTimer", , False
End Sub

Step 2: 또 하나의 예제 - 차트 움직이기

이것으로 오늘 강좌 끝… 하려니까 뭔가 아쉽지요? 또다른 예제 하나를 보도록 합니다. 버튼을 누르세요.

아주 형이상학적(?)인 히안한 모양들이 마구마구 생겨나지요? 이와 같은 것을 Hypocycloid Curve라고 한다는군요. Stage 시트에 입력되어 있는 복잡한 수학공식은 Exceller도 잘 모르는 내용이니까 싸인과 코싸인 값을 가지고 어떻게 이러한 모양이 나오는 지에 대해서는 질문하지 마시기 바랍니다. ^^ 중요한 것은 그것이 아니니까요.

Sub MakeChart()
    datTime = Now + TimeSerial(0, 0, 1)

    ActiveSheet.Calculate
    Application.OnTime datTime, "MakeChart"
End Sub

Sub StopMakeChart()
    On Error Resume Next
    Application.OnTime datTime, "MakeChart", , False
End Sub

위 코드에 대한 설명은 생략합니다. 시계 만드는 과정과 거의 같으니까요. 많이들 응용해 보시기 바랍니다.

마무리

다음 시간에…

정리 — OnTime 시계 핵심

자주 묻는 질문 (FAQ)

마치며

OnTime의 재귀적 호출 구조를 이해하면 시계는 물론 일정 시간마다 반복되는 작업을 쉽게 만들 수 있습니다.