특정 글자색 합계 구하기

Step 1: 예제 데이터와 실행 결과

이제 아래의 버튼을 누른 다음, 위 데이터 영역 내에 있는 임의의 셀을 선택해 보시기 바랍니다.

질문 내용처럼 사용자가 선택한 글자색을 가진 자료들의 합계가 구해지지요?

Step 2: SumByFontColor 프로시저

Sub SumByFontColor()
    Dim rngTarget As Range
    Dim rngFont As Range
    Dim rngCell As Range
    Dim rngSame As Range
    Dim Msg As String
    On Error GoTo ET
    '//변수들을 선언해 줍니다. 만약 에러가 발생했을 경우에는 ET로 갑니다.

    Set rngTarget = Range("MyRange")
    Set rngFont = Application.InputBox("합계를 구할 글자색 셀을 선택하세요", _
        "셀 선택//By Exceller", Type:=8, Default:=rngTarget.Cells(1).Address)
    '//사용자가 합계를 구하고자 하는 글자색이 있는 셀을 마우스로 선택할 수 있도록
    '//설정합니다. 디폴트 값으로 MyRange 영역의 첫번째 셀이 InputBox 내에 나타나도록
    '//지정해 주었습니다.
    '//여기서 MyRange라는 영역은 위의 분홍색 부분으로 미리 정의해 두었습니다.

    If rngFont.Cells.Count > 1 Then
        Msg = Msg & "유효하지 않은 셀을 선택하셨습니다" & vbCr
        Msg = Msg & "범위를 다시 선택하세요"
        MsgBox Msg, , "선택 오류//By Exceller"
        Exit Sub
        '//두 개 이상의 셀이 지정된 경우, 에러 메시지를 출력하고 프로시저를 빠져 나갑니다.
    End If

    For Each rngCell In rngTarget
        If rngCell.Font.ColorIndex = rngFont.Font.ColorIndex Then
            If rngSame Is Nothing Then
                Set rngSame = rngCell
            Else
                Set rngSame = Union(rngSame, rngCell)
            End If
        End If
        '//순환문을 돌면서 지정한 셀의 폰트 색상과 같은 셀을 발견할 경우, 그 셀을
        '//rngSame 변수에 Union으로 차곡차곡 합쳐 둡니다.
    Next rngCell
    If rngSame Is Nothing Then Exit Sub
    '//rngSame에는 사용자가 지정한 글자색과 같은 색을 가진 셀들이 들어 있습니다.

    rngSame.Font.ColorIndex = 2
    rngSame.Interior.ColorIndex = 1
    Msg = "선택하신 색 글자의 합계는 " & vbCr & vbCr
    Msg = Msg & Format(Application.Sum(rngSame), "#,##0.000") & vbCr
    Msg = Msg & "입니다"
    MsgBox Msg, , "합계//By Exceller"
    '//시각적인 효과를 위해 대상 셀의 글자색 및 Interior 속성을 다른 색으로 지정합니다.
    '//선택된 Range 오브젝트의 숫자들을 더하는 것은 Sum 함수를 사용하시면 되겠지요?

ET:
End Sub

Step 3: 셀 색상별 합계로 응용하기

이렇게 하시면 되겠지요? 그렇다면 글자색이 아니라 셀 색상에 따라 합계를 구하려면 어떻게 하면 될까요? 이것도 간단합니다. Range 오브젝트의 프로퍼티명만 바꾸어 주면 될 것입니다. 이 정도면… 아! 하는 감탄사가 나와야 하는데…

즉, 글자색에 접근할 때에는 Range 오브젝트의 Font 속성을 사용하였으니까 이번에는 Interior 속성을 변경해 주시면 됩니다. 위의 코드를 약간만 수정하면 될 테니까 설명은 생략합니다.

마무리

오늘은 여기까지…

정리 — 글자색 합계 핵심

자주 묻는 질문 (FAQ)

마치며

속성 이름만 바꾸면 글자색뿐 아니라 셀 색상별 합계도 같은 방법으로 구할 수 있습니다.