현재시트를 메일로 보내기

Step 1: 질문 살펴보기

메일 중에서 낯익은 ID가 보이면 반갑습니다. '아, 아직 열심히 하고 계시구나!'하는 생각에서… 한동안 열심히 질문을 하시다가 어느 날부터인가 소식이 뜸하면 안타깝습니다. '이제 다른 살길(?)을 찾아가셨나?'하는 생각에서…

위의 질문하신 분은 Exceller's Home 초기 때부터 들러 가끔 질문을 하시던 분인데 한동안 소식이 없다가 다시 연락을 주신 분입니다. 그래서 더욱 반갑기도 하고요. ^^

워크북(파일) 단위로 전송하는 방법에 대해서는 VB0043에서 이미 설명을 드린 기억이 납니다. 아시는 바와 같이 SendMail Method를 사용하시면 됩니다. 아주 간단하니까 VB0043 강좌를 살펴보도록 하시고…

워크시트 단위로 전송하는 것은… 글쎄요 다른 방법도 있겠으나 해당 시트의 내용을 문자열 데이터로 만든 다음 이것을 상대방의 메일 계정으로 전송하는 방법을 택해 보았습니다.

Step 2: 실행해 보기와 참조 설정

일단 아래의 버튼을 누른 다음 메일을 받고자 하는 E-mail 계정을 입력해 보세요. Outlook이 아닌 다른 메일 프로그램을 사용하시는 분을 위해 결과를 메일이 아닌 메시지 박스에 출력하도록 해 보았습니다. Outlook을 사용하시는 분들은 코드 중에서 주석처리된 부분의 '를 없앤 다음 실행해 보시면 될 것입니다. 참고로 Exceller는 Outlook을 사용하지 않기 때문에 잘 작동하는지 테스트는 해 보지 못했습니다.

이 프로시저가 정상적으로 실행되도록 하기 위해서는 먼저 "참조" 지정을 해 주어야 합니다. VB Editor 상태에서 "도구-참조" 메뉴를 선택하고 "사용 가능한 참조 목록"에서 "Microsoft Outlook 9.0 Object Library"를 체크합니다.

Step 3: SendActiveSheet 프로시저

체크를 하셨으면 아래와 같은 코드를 모듈시트에 작성합니다.

Sub SendActiveSheet()
    Dim MyOlApp As Outlook.Application
    Dim shtSheet As Worksheet
    Dim MyNameSpace As NameSpace
    Dim strMail As String
    Dim MyMailItem As MailItem
    Dim varTemp As Variant
    Dim strName As String
    '//등장인물과 배역을 설정합니다. 어럽쇼? 그런데 새로운 인물들이 몇 명 등장했지요?
    '//VB0073 강좌인가에서 파워포인트를 실행시킬 때
    '//Dim pptApp As PowerPoint.Application
    '//이런 식으로 선언해 준 적이 있었는데 기억이 나시는지?
    '//파워포인트나 워드에도 VBA 엔진이 내장되어 있으므로 해당 애플리케이션의
    '//오브젝트를 EXCEL에서 불러다 사용하기 위해 지정을 하는 부분입니다.
    '//Outlook도 당연히(!) VBA를 지원합니다.

    Set shtSheet = ActiveSheet
    strName = shtSheet.Name
    strMail = InputBox("전송할 E-mail 주소를 입력하세요", "메일 주소 입력//Exceller", _
         "exceller@netian.com")
    If Len(strMail) = 0 Or InStr(strMail, "@") = 0 Then
        MsgBox "E-mail 주소가 잘못 되었습니다", , "주소 입력 오류//Exceller"
        Exit Sub
    End If
    '//전송하고자 하는 E-mail 계정을 사용자로부터 입력받은 다음, 이것이 유효한 계정인지
    '//아닌지를 검사합니다.

    Set MyOlApp = CreateObject("outlook.application")
    Set MyNameSpace = MyOlApp.GetNamespace("MAPI")
    'MyNameSpace.Logon
    '//Outlook Application 오브젝트를 생성합니다. 파워포인트를 실행할 때에는
    '//Powerpoint.Application, 워드를 실행할 때에는 Word.Application이라고 했었지요?
    '//그리고 NameSpace라는 새로운 오브젝트가 하나 사용되었는데 이것은 "개체 자체에서
    '//로그인과 로그아웃, ID로 저장 개체를 바로 액세스 하는 등의 기능을 수행" 합니다.
    '//Application 개체에서 Outlook NameSpace 개체를 반환할 때, GetNamespace("MAPI")를
    '//사용합니다. 이것은 사용자의 메일 저장소에 저장된 모든 아웃룩 데이터를 액세스할 수
    '//있도록 해 줍니다.

    '//NameSpace, MailItem 오브젝트 등에 대한 보다 자세한 것은 도움말을 참고하시기 바랍니다.

    varTemp = GetData(shtSheet.UsedRange)
    '//현재 시트 중에서 사용된 영역을 GetData라는 사용자 정의 함수의 인수로 건네주어 함께
    '//실행되도록 한 다음, 그 결과값을 다시 돌려 받습니다.

    Set MyMailItem = MyOlApp.CreateItem(olMailItem)
    '//MailItem 오브젝트는 받은 메일 폴더에 있는 메일 메시지를 나타냅니다. CreateObject 메서드를
    '//사용해서 새로운 메일 메시지를 나타내는 MailItem 개체를 생성합니다. MailItem 오브젝트에
    '//대해서도 도움말을 살펴보시기 바랍니다.

    'With MyMailItem
    '    .Recipients.Add strMail
    '    .Subject = strName
    '    .Body = varTemp
    '    .Send
    'End With
    'MyNameSpace.Logoff
    'MyOlApp.Quit
    '//만약 Outlook을 사용하는 분이라면 위의 녹색 부분에 있는 '을 모두 제거한 다음 실행시키면
    '//되겠습니다.

    MsgBox varTemp
    Set shtSheet = Nothing
    Set MyNameSpace = Nothing
    Set MyOlApp = Nothing
End Sub

Step 4: GetData 함수

이제 사용자 정의 함수인 GetData()의 내용을 보도록 합니다. 특별한 내용이 있는 것은 아니고 현재 워크시트에 있는 내용을 문자열로 바꾼 다음 그 결과값을 돌려주는 내용입니다.

Function GetData(rngRange As Range) As String
    Dim i As Integer
    Dim intStart As Integer
    Dim intEnd As Integer
    Dim r As Long
    Dim lngStart As Long
    Dim lngEnd As Long
    Dim strTemp As String

    With rngRange
    '//현재 워크시트의 사용된 영역의 시작행, 열, 끝행, 열의 위치를 파악하여 변수에 담습니다.

        intStart = .Column
        intEnd = .Column + .Columns.Count - 1
        lngStart = .Row
        lngEnd = .Row + .Rows.Count - 1
    End With

    For r = lngStart To lngEnd
    '//순환문을 돌면서 각 셀의 내용을 strTemp라는 변수에 담아 둡니다.

        For i = intStart To intEnd
            strTemp = strTemp & rngRange.Worksheet.Cells(r, i) & vbTab
        Next i
        strTemp = strTemp & vbCr
    Next r
    GetData = strTemp
End Function

마무리

여러 프로그램을 사용해 본 분일수록 EXCEL이 얼마나 대단한 프로그램인지, 그리고 EXCEL의 분석기능이 Powerful한 것인지 뼈저리게 느끼게 됩니다.

다음 시간에…

정리 — 메일 전송 핵심

자주 묻는 질문 (FAQ)

마치며

시트 내용을 문자열로 바꾸어 Outlook 메일 본문에 담으면 워크시트 단위로 메일을 보낼 수 있습니다.