홀수/짝수 페이지 인쇄하기

Step 1: 실행 방법과 폼 만들기

지난 강좌와 마찬가지로 "미리보기" 항목을 클릭하면 매번 "닫기" 버튼을 눌러야 하기 때문에 번거롭다고 생각하는 분이 있으실 지 모르겠습니다만 이것은 여러분들에게 보여드리기 위한 것이고, 실제 출력을 하실 때는 "프린터로…" 항목을 누르시면 됩니다.

(1) VB Editor 상태에서 UserForm을 하나 삽입하고 아래와 같이 컨트롤들을 그려 넣습니다.

아이엑셀러

Step 2: 정상 인쇄 - 미리보기 버튼 코드

(2) "정상 인쇄" 부분에 있는 "미리보기" 옵션 버튼을 더블클릭하고 아래와 같은 코드를 작성합니다.

지난 시간의 코드는 Unload Me 다음에 GeneralOrderPrint True만 호출하는 형태였습니다.

Private Sub optNormalPreview_Click()
    Dim bytPage As Byte
    '//홀수면을 인쇄할 것인지 아니면 짝수면을
    '//인쇄할 것인지에 대한 선택을 받기 위한
    '//변수를 선언해 주었습니다. Byte 변수는
    '//여러 변수타입 중에서 크기가 가장 작은
    '//것입니다.

    If chkOdd Then
        bytPage = 1
    ElseIf chkEven Then
        bytPage = 2
    Else
        bytPage = 3
    End If
    '//홀수면 인쇄 체크박스가 선택되었으면 bytPage 변수에 1을, 짝수면 인쇄이면 2를,
    '//그 이외의 경우라면 3을 Assign, 즉 대입시킵니다.

    Unload Me
    GeneralOrderPrint True, bytPage
    '//이 부분이 중요합니다! 지난 시간에는 정상순서 인쇄인가 아니면 역순 인쇄인가만을
    '//선택받아서 처리를 하면 되었으나 여기에다가 한 가지 조건 분기가 더 필요하므로
    '//그 처리를 위한 변수를 하나 더 사용하였습니다.

End Sub

Step 3: 정상 인쇄 - 프린터로 버튼 코드

(3) Shift + <F7>키를 눌러 UserForm을 다시 호출한 다음, "정상 인쇄" 프레임 내의 "프린터로…" 항목을 더블클릭하고 필요한 코드를 입력합니다.

Private Sub optNormalPrinting_Click()
    Dim bytPage As Byte

    If chkOdd Then
        bytPage = 1
    ElseIf chkEven Then
        bytPage = 2
    Else
        bytPage = 3
    End If
    Unload Me
    GeneralOrderPrint False, bytPage
    '//다른 것은 위의 (2)와 똑같은데 False 값을 건네준다는 점이 다릅니다.

End Sub

Step 4: GeneralOrderPrint 프로시저

(4) 모듈시트를 한장 삽입합니다. GeneralOrderPrint 프로시저는 일반 모듈시트에 작성을 합니다.

Sub GeneralOrderPrint(ByVal OK As Boolean, _
    Optional ByVal EvenOrOdd As Byte)
    '//프로시저를 시작할 때부터 예사롭지 않게 시작하였지요? ^^ 이벤트 핸들러 프로시저에서
    '//두 개의 변수를 건네받았으니 매개변수도 두 개를 사용하여야 하기 위한 것입니다.
    '//여기서 Optional이라는 것은 선택적 변수라는 것으로, 이것은 사용을 할 수도, 하지 않을
    '//수도 있다는 것입니다. 즉 필수사양이 아니라 옵션사양이라는 의미입니다.

    Dim intTotalPage As Integer
    Dim i As Integer
    intTotalPage = ExecuteExcel4Macro("get.document(50)")

    If EvenOrOdd = 1 Then
        For i = 1 To intTotalPage Step 2
            ActiveSheet.PrintOut from:=i, To:=i, preview:=OK
        Next i
    ElseIf EvenOrOdd = 2 Then
        For i = 2 To intTotalPage Step 2
            ActiveSheet.PrintOut from:=i, To:=i, preview:=OK
        Next i
    Else
        For i = 1 To intTotalPage
            ActiveSheet.PrintOut from:=i, To:=i, preview:=OK
        Next i
    End If
    '//코드를 잔뜩 길게 써 놓았지만 개념 자체는 아주 간단합니다. EvenOrOdd라는 변수는
    '//Optional 변수, 즉 선택적 변수로서 사용자가 짝수 인쇄 항목을 눌렀는지 아니면 반대의
    '//것을 눌렀는지에 대한 정보를 담고 있습니다. 그래서 이것을 조건분기문을 사용하여
    '//각 상황에 맞는 처리를 해 주면 되는 것이지요. EvenOrOdd 변수에 1이라는 값이 담겨져
    '//있으면 홀수인쇄, 2가 담겨져 있으면 짝수인쇄, 이도저도 아니면 모든 페이지를 인쇄하게
    '//되는 것입니다.

    '//나머지 사항에 대해서는 지난 강좌에서 설명을 드렸으므로 생략!

End Sub

Step 5: 역순 인쇄 - ReverseOrderPrint 프로시저

이상의 것이 정상인쇄 및 그에 따른 홀수면/짝수면 인쇄와 관련된 것입니다. 역순으로 인쇄하는 것은 이것과 대동소이 하지요? 즉, 다른 것은 거의 비슷한데 For ~ Next 순환문을 돌 때 맨 나중의 것부터 시작해서 마이너스 Step으로 순환한다는 것이 다를 뿐이지요.

Sub ReverseOrderPrint(ByVal OK As Boolean, _
    Optional ByVal EvenOrOdd As Byte)
    Dim intTotalPage As Integer
    Dim i As Integer
    intTotalPage = ExecuteExcel4Macro("get.document(50)")

    If EvenOrOdd = 1 Then
        For i = intTotalPage - ((intTotalPage + 1) Mod 2) To 1 Step -2
            ActiveSheet.PrintOut from:=i, To:=i, preview:=OK
        Next i
    ElseIf EvenOrOdd = 2 Then
        For i = intTotalPage - (intTotalPage Mod 2) To 2 Step -2
            ActiveSheet.PrintOut from:=i, To:=i, preview:=OK
        Next i
    Else
        For i = intTotalPage To 1 Step -1
            ActiveSheet.PrintOut from:=i, To:=i, preview:=OK
        Next i
    End If
    '//홀수면은 가장 큰 홀수 페이지부터, 짝수면은 가장 큰 짝수 페이지부터 시작하도록
    '//시작값을 정해 주는 부분이 정상 인쇄와 다릅니다.
End Sub

위에서 굵게 표시한 부분이 아마 다를 것입니다. 왜 이렇게 해 주었는지 곰곰이 생각해 보도록 하세요. 물론 이런 방법이 아닌 다른 방법도 있을 것입니다.

마무리

오늘은 여기까지…

정리 — 홀짝 인쇄 핵심

자주 묻는 질문 (FAQ)

마치며

체크박스 값을 하나의 변수로 넘기고 순환문의 시작값과 Step만 바꾸면 홀수면, 짝수면, 역순 인쇄를 모두 처리할 수 있습니다.