역순으로 인쇄하기

Step 1: 인쇄 방법 선택 유저폼 만들기

(1) VB Editor 상태에서 UserForm을 하나 삽입하고 아래와 같이 컨트롤들을 그려 넣습니다.

아이엑셀러

Step 2: 정상 인쇄 - 프린터로 버튼

(2) "정상 인쇄" 부분에 있는 "프린터로…" 옵션 버튼을 더블클릭하고 아래와 같은 코드를 작성합니다.

Private Sub optNormalPrinting_Click()
    Unload Me
    GeneralOrderPrint False
    '//코드 자체는 아주 간단합니다. 유저폼을 Unload시키고 GeneralOrderPrint라는
    '//프로시저를 호출합니다. 이 때 False값을 건네주어 함께 실행되도록 합니다.

End Sub

Step 3: 정상 인쇄 - 미리보기 버튼

(3) 이번에는 "정상 인쇄"의 "미리보기" 옵션 버튼을 더블클릭하고 아래의 코드를 입력합니다.

Private Sub optNormalPreview_Click()
    Unload Me
    GeneralOrderPrint True
    '//다른 것은 위 (2)에서 작성한 것과 똑같고… GeneralOrderPrint 프로시저를 실행할 때
    '//True값을 건네준다는 것만 다릅니다.

End Sub

Step 4: GeneralOrderPrint 프로시저

(4) 이제 GeneralOrderPrint 프로시저의 내용을 살펴보아야 겠지요? 이 프로시저는 이벤트 핸들러 프로시저가 아니라 일반 프로시저이므로 General VBA 모듈시트, 즉 보통의 모듈시트를 한장 삽입하고 여기에 작성합니다.

Sub GeneralOrderPrint(ByVal OK As Boolean)
    '//프로시저를 시작할 때 외부에서 변수를 받아와서 사용하였지요? 이와 같은 변수를…
    '//그렇지요! 파라미터 변수, 즉 매개변수라고 합니다. 어떤 프로시저로부터 값을
    '//전달받느냐에 따라 True 또는 False값이 저장되는 것이지요.

    Dim intTotalPage As Integer
    Dim i As Integer
    intTotalPage = ExecuteExcel4Macro("get.document(50)")
    '//이 부분에서 XLM 매크로가 사용되었군요. Get.document(50)은 현재 워크시트의
    '//전체 페이지수를 돌려줍니다.

    For i = 1 To intTotalPage
        ActiveSheet.PrintOut from:=i, to:=i, preview:=OK
        '//전체 페이지가 몇 페이지인지를 알았으니까 For ~ Next 순환문을 돌면서 원하는
        '//작업을 해 주면 되겠지요?

    Next i
End Sub

여기까지가 정상 방향으로 인쇄를 하는 과정이었습니다. 사실 이것은 이렇게 여러 단계를 거치고 말고 할 것도 없지요. 그냥 "미리보기" 또는 "인쇄" 아이콘을 클릭하기만 하면 되지만 기본적인 구현원리를 살펴보기 위해 좀 장황하게 설명을 드렸습니다.

그런데 아마 눈치가 빠른 분이라면 이미 답을 짐작하실 지도 모르겠습니다. (4)의 프로시저의 내용을 약간만 손질하면 되니까요. ^^

Step 5: 역순 인쇄 - 프린터로 버튼

(5) "역순 인쇄"의 "프린터로…" 옵션 버튼을 더블클릭 한 다음 코드를 작성합니다.

Private Sub optReverseOrderPrinting_Click()
    Unload Me
    ReverseOrderPrint False
End Sub

Step 6: 역순 인쇄 - 미리보기 버튼

(6) "미리보기" 옵션버튼을 더블클릭하고 다음의 코드를 작성합니다.

Private Sub optReverseOrderPreview_Click()
    Unload Me
    ReverseOrderPrint True
End Sub

Step 7: ReverseOrderPrint 프로시저

(7) 역순인쇄를 위한 코드를 작성합니다. 이 부분이 오늘의 핵심입니다. 보시는 바와 같이 (4)에서 작성한 코드와 거의 비슷합니다.

Sub ReverseOrderPrint(ByVal OK As Boolean)
    Dim intTotalPage As Integer
    Dim i As Integer
    intTotalPage = ExecuteExcel4Macro("get.document(50)")

    For i = intTotalPage To 1 Step -1
    '//전체 페이지 수를 XLM 매크로를 사용하여 알아낸 다음 For ~ Next 순환문을 돌되
    '//맨 뒷장부터 출력을 해야 하므로 For I=intTotalPage To 1 Step -1 과 같은 형태로
    '//합니다.

        ActiveSheet.PrintOut from:=i, to:=i, preview:=OK
    Next i
End Sub

마무리

다음 시간에…

정리 — 역순 인쇄 핵심

자주 묻는 질문 (FAQ)

마치며

XLM 매크로로 페이지 수를 구하고 순환 방향만 바꾸면 역순 인쇄를 간단히 구현할 수 있습니다.