분산형 차트 응용

Step 1: 오늘의 질문

즉, 지점별 실적(가로축)과 이익(세로축)이 만나는 위치에 지점명이 데이터 레이블로 표시되도록 하고 싶다는 질문입니다.

Step 2: 분산형 차트로 만들어 보기

아래와 같은 지점별 매출액과 경상이익 표가 있다고 가정합니다.

이것을 가지고 차트를 만들면 아래와 같은 형태가 될 것입니다. 그런데 어떻게 만들었나고요? 분산형 차트를 사용하시면 됩니다.

표에서 데이터 부분, 즉 지점명을 제외한 매출액과 경상이익 값만 선택한 다음 "분산형" 차트를 지정해 보세요.

대충 모양은 비슷한데 뭔가가 빠진 듯 하지요? 경상이익과 매출액을 축으로 하여 두 항목이 만나는 지점에 표시를 해 준 것 까지는 좋은데 각각의 네모가 어느 지점을 가리키는 것인지 알려면 한참을 들여다 보아야 합니다. 이런 자료를 윗분께 보고드리면 일은 일대로 하면서 욕얻어 먹기 딱 좋지요. 가뜩이나 눈도 침침한데 해괴한(?) 것을 갖고와서

따라서 각 네모마다 지점명을 표시해 주기만 하면 될 것 같은데… 차트와 관련된 여러 가지 속성값을 변경해 주면 간단하게 해결이 될 것 같지만 더 이상은 방법이 없습니다. 혹시 방법을 아시는 분은 연락주시기 바랍니다.

하지만 그렇다고 해서 여기서 순순히 포기할 Exceller가 아니지요? ^^ 워크시트 상에서 수작업 조작을 통해서는 불가능하지만 VBA의 도움을 받으면 해결을 할 수 있습니다.

Step 3: DisplayLabel 프로시저

Sub DisplayLabel()
    Dim rngBranch As Range
    Dim chtMyChart As Chart
    Dim i As Integer
    Dim intBranch As Integer
    '//늘 그래왔듯이 등장인물, 즉 필요한 변수들을 먼저 지정합니다.

    Set chtMyChart = ActiveSheet.ChartObjects(2).Chart
    On Error Resume Next
    Set rngBranch = Range("지점명")
    '//현재 시트에 두 개의 시트가 있는데 이 중에서 두번째 차트를 대상으로 하기 위해
    '//변수에 담아두고, 레이블로 사용할 지점명 부분도 rngBranch라는 변수에 담습니다.

    chtMyChart.SeriesCollection(1).ApplyDataLabels _
        Type:=xlDataLabelsShowValue, AutoText:=True
    '//SeriesCollection 메서드는 차트나 차트 그룹에 있는 하나(또는 전체)의 계열을
    '//지정할 때 사용하게 됩니다. ApplyDataLabels 속성은 계열에 이름표를 표시하는
    '//속성입니다. 그리고 AutoText는 문맥에 따라 해당하는 텍스트를 자동으로 생성하는
    '//속성입니다.

    '//EXCEL에는 여러 개의 오브젝트가 있습니다만 그 중에서 가장 다양한 속성을 가진
    '//것이 바로 차트 오브젝트 입니다. 따라서 위에서 설명드린 속성들은 물론이려니와
    '//그 밖의 다른 속성들과 메서드에 대해서도 도움말을 찾아보시기 바랍니다.

    intBranch = chtMyChart.SeriesCollection(1).Points.Count
    '//Points는 "차트의 계열에 있는 하나의 데이터 요소"를 의미합니다. 따라서 이 문장은
    '//첫번째 계열안에 몇 개의 요소가 있는지를 카운팅해서 해당값을 intBranch 변수에
    '//저장하는 것입니다.

    '//그런 다음에 포인트 수만큼 순환문을 돌면서 DataLabel의 값을 차트 상에 표시하는
    '//것입니다.

    For i = 1 To intBranch
        With chtMyChart.SeriesCollection(1).Points(i).DataLabel
            .Characters.Text = rngBranch.Cells(i)
            .Font.Size = 10
        End With
    Next i
End Sub

Step 4: 레이블 삭제하기

그리고 레이블을 삭제하는 코드는 아래와 같습니다. 간단하지요. 너무 간단해서 설명하고 말고 할 것도 없는 것 같고… HasDataLabel 속성을 False로 지정하면 됩니다.

Sub DelDataLabel()
    Dim chtMyChart As Chart
    Set chtMyChart = ActiveSheet.ChartObjects(2).Chart

    chtMyChart.SeriesCollection(1).HasDataLabels = False
End Sub

마무리

다음 시간에…

정리 — 차트 레이블 핵심

자주 묻는 질문 (FAQ)

마치며

수작업으로 어려운 차트 레이블도 VBA의 Points와 DataLabel을 활용하면 자동으로 표시할 수 있습니다.