사용자 정의 변수에 대하여

Step 1: 사용자정의 변수란?

보통 변수는 Integer, String, Date, Single, Long 등과 같이 정해진 타입이 있습니다. 변수란 쉽게 말하자면 (값을 저장해 두는) 그릇입니다. 그런데 그릇에도 여러 가지 종류가 있지요? 큰 가마솥에서부터 간장 종지에 이르기까지 크기에 따라 쓰임새가 다 다릅니다.

그런데 "사용자정의 변수"라는 것은 쉽게 말하자면, 여행갈 때 사용하는 "코펠" 이라고 할 수 있습니다. "여러 형태의 그릇(변수) 여러 개를 한데 합쳐놓은 것" 이지요.

아래의 표를 보시기 바랍니다.

이 예제에서 사용한 표는 다음과 같습니다(Start 셀이 표의 첫 칸이며 이름은 임의로 만든 예시입니다).

여기에서 이름은 문자열(String) 타입 변수, 전화번호도 문자열(String) 타입 변수, 주소, 회사명, 직책도 문자열(String) 타입 변수, 연봉은 통화형(Currency) 변수이지요?

Step 2: Type 문으로 큰 그릇 만들기

이러한 정보를 담아두기 위한 그릇을 모두 따로 만들어 두는 것이 아니라

Type CustInfo
    strName As String * 10
    strTel As String * 10
    strAddress As String * 30
    strCompany As String * 20
    strRank As String * 10
    curPayment As Currency
End Type

이와 같이 CustInfo라는 큰 그릇을 만들어 두고 그 안에 다시 작은 그릇들을 만들어 두는 것입니다. 그리고 이 큰 그릇은 모듈시트에서 특정 프로시저 내부가 아닌 외부에다 선언을 해 둡니다.

Step 3: 사용자정의 변수 사용하기

코드는 아래와 같습니다.

Sub UserDefinedTypeTest()
    Dim typMyInfo() As CustInfo
    Dim Msg As String
    Dim i As Integer
    Dim intCount As Integer
    Dim intNum As Integer
    Dim curTotalPayment As Currency
    i = Range("Start").CurrentRegion.Columns(1).Cells.Count - 2
    ReDim typMyInfo(i)
    '//모듈시트의 도입부분에 사용자정의 변수를 지정해 두었으니까 프로시저에서 그것을 불러
    '//사용하는 것입니다. 불러오는 방법은 "Dim 변수명() As 사용자정의변수명"과 같은 형태로
    '//사용합니다. 여기서는 레코드가 몇 개인지 알 수 없다고 가정하고 동적배열변수를 사용해
    '//보았습니다.

    '//여기서 동적배열변수의 크기를 Redimension문으로 재정의 할 때,
    '//i = Range("Start").CurrentRegion.Columns(1).Cells.Count - 2와 같이 사용하였는데 왜 뒤에
    '//-2를 해 주는지 아시겠습니까? 배열은 다른 조건을 주지않는 한, Lbound의 크기가 0이지요?
    '//거기다가 Start 셀의 CurrentRegion 영역의 첫번째 라인은 타이틀 부분이 있기 때문에
    '//-2를 해 준 것입니다.

    For intCount = LBound(typMyInfo) To UBound(typMyInfo)
        With Range("Start")
            typMyInfo(intCount).strName = .Offset(intCount, 0)
            typMyInfo(intCount).strTel = .Offset(intCount, 1)
            typMyInfo(intCount).strAddress = .Offset(intCount, 2)
            typMyInfo(intCount).strCompany = .Offset(intCount, 3)
            typMyInfo(intCount).strRank = .Offset(intCount, 4)
            typMyInfo(intCount).curPayment = .Offset(intCount, 5)
        End With
        '//배열의 크기만큼 순환문을 돌면서 큰 그릇(사용자정의 변수) 안에 있는 작은 그릇에
        '//해당값들을 종류별로 담습니다.

    Next intCount

    For intCount = LBound(typMyInfo) To UBound(typMyInfo)
        With typMyInfo(intCount)
            Msg = "<" & intCount + 1 & " 번째 데이터의 정보>" & vbCr & vbCr
            Msg = Msg & "이    름:   " & .strName & vbCr
            Msg = Msg & "전화번호:   " & .strTel & vbCr
            Msg = Msg & "주    소:   " & .strAddress & vbCr
            Msg = Msg & "회 사 명:   " & .strCompany & vbCr
            Msg = Msg & "직    책:   " & .strRank & vbCr
            Msg = Msg & "연    봉:   " & .curPayment & " 천원"
        End With
        MsgBox Msg, , typMyInfo(intCount).strName & " 기본 정보//Exceller"
        curTotalPayment = curTotalPayment + typMyInfo(intCount).curPayment
        '//마찬가지로 배열의 크기만큼 순환문을 돌면서 변수에 저장된 값들을 메시지 박스에
        '//뿌려 줍니다.

    Next intCount
    MsgBox "급여총액은 " & Format(curTotalPayment, "#,##0") & " 천원 입니다"
End Sub

마무리

이와 같이 사용자정의 변수를 사용하면 같은 성격의 서로 다른 데이터들을 보다 체계적으로 관리할 수 있게 됩니다. 처음 보시는 분들은 좀 복잡해 보일지 모르겠는데 잘 따져보면 그다지 어려운 것이 아니니까 잘 익혀두시기 바랍니다.

다음 시간에…

정리 — 사용자 정의 변수 핵심

자주 묻는 질문 (FAQ)

마치며

사용자 정의 변수를 활용하면 같은 성격의 서로 다른 데이터를 체계적으로 관리할 수 있습니다.