엑셀에서 파워포인트 실행하기

Step 1: 강좌 파일 준비하기

Excel에서 파워포인트 슬라이드쇼 실행이라… 못할 것도 없지요. 예전에 말씀드린대로 손으로 작업가능한 사항이면 모두 자동화가 가능하다고 생각하시면 아마 틀림이 없을 것입니다.

오늘 강좌 파일은 VB0073.xls와 MyPpt.ppt 파일, 이렇게 2개로 이루어져 있습니다. 압축을 해제하실 때 반드시 같은 폴더 내에 하시기 바랍니다. 그렇지 않으면 제대로 작동하지 않습니다. 확인하셨으면 버튼을 누르세요.

Step 2: 파워포인트 라이브러리 참조 설정하기

(1) VB Editor 상태에서 "도구-참조" 메뉴를 선택합니다.

(2) 그러면 "참조" 대화상자가 나타나는데 "사용 가능한 참조" 목록 중에서 "Microsoft PowerPoint 9.0 Object Libaray"를 선택합니다(Excel 2000 기준입니다. 만약 Excel 97버전이면 Microsoft PowerPoint 8.0 Object Library라는 목록이 나타날 것입니다).

아이엑셀러

Step 3: 슬라이드쇼 실행 코드 작성하기

(3) 모듈시트를 하나 삽입하고 아래의 코드를 작성합니다.

Sub ExePptShow()
    Dim strFile As String
    Dim Msg As String
    Dim pptApp As PowerPoint.Application
    Dim pptShow As PowerPoint.presentation
    On Error Resume Next
    '//먼저 변수를 선언합니다. 그런데 ...PowerPoint.Application, … PowerPoint.presentation
    '//이라고 하는 못보던 변수형이 선언되었군요.
    '//원래 VBA가 Visual Basic for Application, 즉 Visual Basic은 Visual Basic인데 특정한 소프트웨어(Application)을 위한 비주얼 베이직입니다. 따라서 VBA는 Excel에도
    '//있고, 워드에도 있으며 파워포인트나 억세스에도 있습니다.

    '//VBA를 배우면 좋은 것이 해당 소프트웨어를 구입하면 자동으로 따라온다는 점과
    '//(물론 영특한(?) Microsoft社 원가담당 직원이 제품가격 책정시 VBA의 가치도 함께 산정
    '//하였겠지만…) 어느 한 VBA를 마스터하면 다른 애플리케이션의 VBA도 80% 정도는
    '//그냥 건질 수 있다는 점입니다. VBA 중에 가장 오브젝트가 많고 복잡한 편인 Excel의
    '//VBA만 잘 익혀 두면 나머지 애플리케이션용 VBA는 그야말로 땅짚고 헤엄치기 이지요.

    Set pptApp = CreateObject("Powerpoint.Application")
    '//Excel의 최상위 오브젝트가 Application 오브젝트였지요?
    '//파워포인트를 실행시켜야 하니까 파워포인트 애플리케이션 오브젝트를 불러 옵니다.

    pptApp.Visible = True
    strFile = ThisWorkbook.Path & Application.PathSeparator & "MyPpt.ppt"
    Set pptShow = pptApp.Presentations.Open(strFile)
    '//불러올 파일의 위치를 지정하고 파워포인트를 실행시킵니다.

    pptShow.SlideShowSettings.Run
    If Err <> 0 Then GoTo ET
    Set pptApp = Nothing
    Set pptShow = Nothing
    Exit Sub
    '//파워포인트의 슬라이드쇼를 실행시킵니다. 에러가 발생할 경우를 대비하여 에러 트래핑
    '//구문을 하나 만들어 두었습니다.
    '//프로그램을 다 실행한 다음에 Set pptApp=Nothing과 같이 하는 이유는 메모리의 효율적인
    '//관리를 위해서입니다. 즉 변수를 사용한 다음에 메모리를 비워주는 것입니다. 이것도 좋은
    '//습관이니까 몸에 붙이시도록…

ET:
    Msg = "MyPpt 파일이 없거나 파워포인트를 실행할 수 없습니다" & vbCr & vbCr
    Msg = Msg & "확인바랍니다."
    MsgBox Msg, vbCritical, "실행 오류//Exceller"
End Sub

마무리

간단하지만 활용여하에 따라 유용하게 사용하실 수 있으리라 생각됩니다.

오늘은 여기까지…

정리 — 파워포인트 실행 핵심

자주 묻는 질문 (FAQ)

마치며

CreateObject로 파워포인트 개체를 만들면 엑셀 버튼 하나로 슬라이드쇼까지 자동으로 실행할 수 있습니다.