두 개의 콤보박스 링크하기

Step 1: 두 콤보박스를 연결하는 두 가지 방법

두 개의 콤보박스를 연결하여 사용하는 것, 즉 이쪽 콤보박스에서 어떤 항목이 선택되느냐에 따라 다른 콤보박스의 항목이 다르게 리스팅되게 하는 방법은 크게 두 가지로 나누어 볼 수 있습니다. 일반 워크시트 상에서 하는 것과, UserForm에서 하는 것이 바로 그것입니다.

일반 워크시트 상에서는 "유효성 검사"를 응용해서 "이중 유효성 검사"를 설정하는 것으로, 이것은 VB0023 강좌에서 상세히 설명을 드렸으니까 참고하시기 바랍니다.

이번 시간에는 또 한 가지 방법인 유저폼 상에서 이것을 가능하도록 하는 방법에 대해 설명을 드리도록 하겠습니다. 우선 백문이 불여일견 이니까… 아래 버튼을 눌러 예제를 실행시켜 보세요.

이 프로그램은 다음과 같은 세 부분으로 구분할 수 있습니다.

• (1) 유저폼을 띄울 때, 초기 값들을 설정하는 부분
• (2) 첫번째 콤보박스의 결과에 따라 두번째 콤보박스의 내용을 지정하는 부분
• (3) 각 항목 선택이 끝났을 때 유저폼의 선택사항들을 워크시트로 옮기는 부분

예제에 사용한 계정 시트는 아래와 같으며, 각 열에 이름이 정의되어 있어 두 번째 콤보박스의 목록으로 사용됩니다(급여, 식비, 의생활, 공과금, 육아교육, 교통비).

Step 2: 유저폼 만들기

이제 본격적으로 만들어 볼까요?

(1) VB Editor를 실행시키고 UserForm을 하나 삽입합니다. 아래의 그림을 참고로 필요한 컨트롤들을 그려 넣습니다.

아이엑셀러

어떤 컨트롤들이 사용되었는지 아시겠지요? 3개의 Label, 2개의 콤보박스, 1개의 텍스트박스, 2개의 커맨드버튼, 1개의 이미지 컨트롤 등 모두 4종류, 9개의 컨트롤이 사용되었습니다.

Step 3: 초기값 정의하기

(2) 유저폼이 처음 실행될 때 기본값을 정의하는 프로시저를 작성합니다. 유저폼 중에서 컨트롤이 없는 빈 영역을 더블클릭하고 이벤트 선택상자에서 Initialize 이벤트를 선택한 다음, 코드를 작성합니다.

Private Sub UserForm_Initialize()
    '//유저폼의 기본값을 정의하는 프로시저입니다. 두 콤보박스의 default값으로 아무 것도
    '//선택되지 않게하고 두 번째 콤보박스 위에 있는 리스트 박스의 캡션을 지정합니다.

    With Me
        .cmbBox1.Value = ""
        .cmbBox2.Value = ""
        .cmbBox1.RowSource = "계정"
        .lblCost = "비목"
    End With
End Sub

Step 4: 첫 번째 콤보박스 Change 이벤트 작성하기

(3) Shift + <F7>키를 눌러 유저폼을 호출하고, 첫번째 콤보박스를 클릭한 다음, 이벤트 선택 상자에서 이번에는 Change 이벤트를 선택하고 코딩을 합니다.

Private Sub cmbBox1_Change()
    '//콤보박스의 Change 이벤트를 사용하여, 어떤 항목이 선택되었는가에 따라 두번째 콤보
    '//박스의 RowSource 영역을 서로 다르게 지정해 줍니다.

    With Me
        Select Case cmbBox1.ListIndex
            Case 0
                .lblCost = "급여 비목"
                cmbBox2.RowSource = "급여"
            Case 1
                .lblCost = "식비 비목"
                cmbBox2.RowSource = "식비"
            Case 2
                .lblCost = "의생활 비목"
                cmbBox2.RowSource = "의생활"
            Case 3
                .lblCost = "공과금 비목"
                cmbBox2.RowSource = "공과금"
            Case 4
                .lblCost = "육아교육 비목"
                cmbBox2.RowSource = "육아교육"
            Case 5
                .lblCost = "교통비 비목"
                cmbBox2.RowSource = "교통비"
        End Select
    End With
End Sub

Step 5: 확인 버튼 코드 작성하기

(4) 다시 유저폼으로 돌아가서 OK 버튼을 더블클릭하고 아래의 코드를 기입합니다. 이제 이 부분은 워낙 설명을 많이 드렸기 때문에 별도의 설명이 필요없겠지요? ^^

Private Sub btnOK_Click()
    Dim sht As Worksheet
    Dim r As Long
    Set sht = Sheets("WorkPlace")
    r = Application.WorksheetFunction.CountA(sht.Range("A:A")) + 1
    '//WorkPlace 시트의 A열에 순차적으로 자료를 입력하기 위해 현재 A열에 몇 개의 데이터가
    '//들어 있는지 카운팅해서 거기다 1을 더해 준 수를 변수 r에 넣어 둡니다.

    If txtMoney.Text = "" Or Not IsNumeric(txtMoney.Text) Then
    '//[금액] 입력란에 아무 값도 입력되지 않았거나 숫자가 아닌 값이 입력되었을 경우
    '//사용자에게 다시 입력하도록 하기 위한 부분입니다.

        MsgBox "금액은 반드시 숫자를 입력하세요", , "금액 입력//Exceller"
        With txtMoney
            .SetFocus
            .SelStart = 0
            .SelLength = Len(.Text)
        '//이렇게 설정을 해 주면 에러가 발생한 컨트롤에 Focus가 설정되면서 바로 입력할 수
        '//있게 됩니다.
        End With
        Exit Sub
    End If

    sht.sht.Cells(r, 1) = cmbBox1.Value
    sht.sht.Cells(r, 2) = cmbBox2.Value
    sht.sht.Cells(r, 3) = Val(txtMoney.Text)

    cmbBox1.Value = ""
    cmbBox2.Value = ""
    txtMoney.Text = ""
    '//항목들이 정상적으로 선택이 되었다면 이것을 워크시트 상의 각 셀로 옮겨주고 유저폼의
    '//각 컨트롤 값들을 초기화합니다.
End Sub

Step 6: 취소 버튼 코드 작성하기

마지막으로, 닫기 버튼을 클릭했을 때 유저폼을 닫는 코드를 작성합니다.

Private Sub btnCancel_Click()
    Unload Me
End Sub

마무리

오늘은 여기까지…

정리 — 콤보박스 연동 핵심

자주 묻는 질문 (FAQ)

마치며

Change 이벤트에서 RowSource만 바꿔 주면 두 콤보박스를 간단하게 연동할 수 있습니다.