어제없는 오늘은 없습니다: 입력값 누적하기

Step 1: 이런 방식은 권하지 않습니다

이러한 종류의 질문들도 심심찮게 들어옵니다. 무슨 작업을 하시려는지 대충 짐작은 갑니다만 절대로(!) 이렇게는 하지 마시기 바랍니다. 즉 누계 자료가 필요하다면 하루하루의 데이터를 누적시켜 나가면 되는 것이지 어느 셀에다 값을 입력하고 같은 셀에 또다른 값을 입력하면 이전의 값과 자동으로 합산이 되도록 하는 식으로는 작업을 하지 마시라는 것입니다.

물론 그것이 불가능 한 것은 아닙니다. 충분히 가능하다는 것을 오늘 보여드리기 위해 예제를 하나 만들어 보겠지만 실제 업무에서는 이렇게 사용하지 마시고 '이렇게도 쓸 수 있구나!' 하는 것만 이해하시기 바랍니다.

좋은 질문을 주셔서 이 기회에 동적 배열변수의 사용방법과 외부 변수선언에 대해 이 기회에 확실히 이해하고 넘어가도록 하지요.

버튼을 누르면 유저폼이 하나 나타날 것입니다. 값을 입력하고 기간을 지정한 다음, "입력" 버튼을 클릭하면 해당 기간란에 값이 입력됩니다. 몇 개의 값을 입력하신 다음에 "입력 내용 보기" 버튼을 클릭하면 그동안 입력했던 값들이 표시가 됩니다.

예제 시트의 결과는 아래와 같은 형태입니다.

Step 2: 셀 이름 정의와 유저폼 만들기

(1) 먼저 각 셀에 이름을 지정하였습니다. First, Second, Third, Total이라고 이름을 지었으니 확인해 보시고…

(2) 아래와 같은 UserForm을 하나 만듭니다.

아이엑셀러

Step 3: 입력 버튼 코드 작성하기

(3) "입력" 버튼을 더블클릭하고 아래와 같은 코드를 작성합니다.

Dim intAllValues() As Integer
Dim i As Integer
'//프로시저 외부에 변수를 선언해 주었습니다. 이 intAllValues 변수는 사용자가 입력한 값들을
'//저장해 두기 위한 것입니다. 그러면 왜 프로시저 내부가 아닌 외부에 선언해 주었을까요?
'//이렇게 해 주면 다른 프로시저에서도 별도의 선언없이 이 변수를 사용할 수가 있습니다.
'//그리고 사용자가 몇 개의 숫자를 입력할 지 알 수 없으므로 배열의 크기를 미리 지정해 주지
'//않고 동적 배열변수로 지정을 하였습니다.

Private Sub btnContinue_Click()
    Dim intTemp As Integer
    Dim intSum As Integer
    Dim intCount As Integer
    '//필요한 변수들을 선언해 주고…

    If Not IsNumeric(txtInput) Then
        MsgBox "반드시 숫자값을 입력하세요", , "입력 오류//Exceller"
        With txtInput
            .SetFocus
            .SelStart = 0
            .SelLength = Len(.Text)
        End With
        Exit Sub
    End If
    '//[입력할 값]란에 숫자값이 아닌 다른 형태의 값이 입력되면 에러 메시지를 표시하고
    '//다시 입력할 것을 사용자에게 알립니다.

    Select Case True
    '//옵션 버튼 중에서 어떤 것이 눌려 졌는지 파악해서 입력받은 값을 해당 셀로 옮겨적는
    '//과정입니다. 이 때 지금까지 입력된 내용을 동적 배열변수에 기억시키는 과정을 눈여겨
    '//보시기 바랍니다.
    '//Preserve 명령어로 배열의 크기를 보존시켜 놓고, 입력된 값을 배열변수 intAllValues(I)에
    '//담습니다.

        Case optFirst
            intTemp = Val(txtInput)
            Range("First") = Range("First").Value + intTemp
            ReDim Preserve intAllValues(i)
            intAllValues(i) = intTemp
        Case optSecond
            intTemp = Val(txtInput)
            Range("Second") = Range("Second").Value + intTemp
            ReDim Preserve intAllValues(i)
            intAllValues(i) = intTemp
        Case optThird
            intTemp = Val(txtInput)
            Range("Third") = Range("Third").Value + intTemp
            ReDim Preserve intAllValues(i)
            intAllValues(i) = intTemp
        Case Else
            MsgBox "기간을 선택하세요", , "기간 선택//Exceller"
            Exit Sub
    End Select

    For intCount = LBound(intAllValues) To UBound(intAllValues)
        intSum = intSum + intAllValues(intCount)
        '//동적 배열변수에 저장된 값들을 모두 더해서 합계를 계산해 둡니다.
    Next intCount
    i = i + 1
    Range("Total") = intSum

    With txtInput
        .Text = ""
        .SetFocus
    End With
    '//합계 부분에 계산된 결과값을 뿌려주고 포커스를 [입력할 값]란으로 옮깁니다.

End Sub

Private Sub UserForm_Initialize()
    Range("First") = 0
    Range("Second") = 0
    Range("Third") = 0
    Range("Total") = 0
    i = 0
End Sub

Private Sub btnExit_Click()
    Unload Me
End Sub

Step 4: 입력 내용 보기 버튼 코드 작성하기

(4) "입력 내용 보기" 버튼을 눌렀을 때 지금까지 입력된 값들을 모두 보여주기 위한 코드를 작성합니다.

Private Sub btnShowInputData_Click()
    Dim i As Integer
    Dim strTemp As String
    Dim Msg As String
    On Error Resume Next

    For i = LBound(intAllValues) To UBound(intAllValues)
        strTemp = strTemp & CStr(intAllValues(i)) & vbCr
        '//배열의 모든 값을 strTemp 변수에 담습니다. 여기서 Lbound와 Ubound에 대해서는
        '//도움말을 찾아보시기 바랍니다.
    Next i
    Msg = "지금까지 입력하신 것은" & vbCr & vbCr
    Msg = Msg & strTemp & vbCr & "입니다"
    MsgBox Msg, , "입력 내용 보기//Exceller"
End Sub

마무리

다시 한번 말씀드리지만, 어제가 있어야 오늘이 있고 오늘을 바탕으로 내일이 있는 것입니다. 하루하루의 데이터를 축적해 두면 누계는 저절로 구해지지요.

오늘은 여기까지…

정리 — 입력값 누적 핵심

자주 묻는 질문 (FAQ)

마치며

어제가 있어야 오늘이 있듯이, 하루하루의 데이터를 쌓아 두면 누계는 저절로 구해집니다.