Modeless 대화상자 만들기

Step 1: Modal과 Modeless

알겠나이다!

우리가 흔히 접하게 되는 대화상자(Dialog Box. Dialog sheet 말고…)를 한번 떠올려 보세요. 예를 들어, "서식-조건부 서식" 메뉴를 선택했을 때 나타나는 대화상자를 생각해 보세요. 생각이 안나면 재빨리 살펴 보고 오시고…

아마도 대부분의 대화상자는 사용자가 어떤 다른 작업을 하려고 하면 현재 화면상에 떠있는 대화상자를 반드시 닫아야만 합니다. 이것을 Modal(모달)이라고 합니다. 그런데 어떤 대화상자는 화면상에 대화상자가 떠 있어도 다른 작업을 계속 진행할 수 있도록 되어 있는 것이 있는데 이것을 Modeless(모달리스)라고 부릅니다.

일단 말로 설명하면 이렇습니다. 절대로 말로 때우는 "Excel에 날개달기" 강좌가 아니니까 예제를 보아야 겠지요? 아래의 버튼을 누르신 다음, 이곳저곳 아무 셀이나 선택해 보세요. 표를 하나 만들어 두는 것이 좋겠군요(아무리 생각해 봐도 Exceller는 지극정성입니다. 이 담에 죽어서 꼬옥 좋은 데 가겠지요? ^___^).

아래와 같은 표를 하나 만들어 두고 실행해 보시기 바랍니다.

어떻습니까? 대화상자가 화면에 떠 있는 상태임에도 불구하고 셀 포인터를 움직일 때마다 해당 셀의 여러 가지 정보들이 대화상자 내부에 마구마구 업데이트 되지요? 이번 시간에는 이러한 Modaless 대화상자를 만들어 보겠습니다. 재미있겠지요?

Step 2: 유저폼 만들기

(1) VB Editor 상태에서 UserForm을 하나 삽입하고 아래와 같이 필요한 컨트롤들을 삽입합니다.

아이엑셀러

위의 빨간 동그라미 친 부분에도 Label이 있으니까 모두 8개의 레이블과 1개의 커맨드 버튼을 그려 넣습니다.

Private Sub cmdClose_Click()
    Unload Me
End Sub

Step 3: ThisWorkbook 이벤트 작성하기

(2) 이 Modaless 대화상자를 만들기 위해서는 여러 종류의 이벤트들 중에서 ThisWorkbook 오브젝트의 SheetActivate 이벤트와 SheetSelectionChange Event를 사용해야 합니다. 따라서 프로젝트 탐색기에서 ThisWorkbook 오브젝트를 더블클릭 하고(그림 참고), 아래와 같은 코드를 코드 모듈에 작성합니다.

아이엑셀러

코드 자체는 별로 설명드릴 것이 없습니다. 워크북 내의 시트가 활성화되거나 시트 중에서 SelectionChange 이벤트가 발생하였을 경우, ShowFormatByModeless라는 프로시저를 호출하는 것입니다.

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    Call ShowFormatByModeless
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    Call ShowFormatByModeless
End Sub

Step 4: 정보를 표시하는 프로시저 작성하기

(3) 이제 아래와 같은 ShowFormatByModeless 프로시저를 작성합니다. 이 부분도 마찬가지로 별로 어려운 것은 없을 것입니다.

Sub ShowFormatByModeless()
    With UserForm1
        .lblCellAddressContent.Caption = ActiveCell.Address(False, False)
        If ActiveCell.HasFormula Then
            .lblFormulaContent.Caption = ActiveCell.Formula
        Else
            .lblFormulaContent.Caption = "공식이 입력된 셀이 아닙니다"
        End If
        .lblFormatContent.Caption = ActiveCell.NumberFormat
        .lblFontName.Caption = ActiveCell.Font.Name & " / " & ActiveCell.Font.Size
    End With
End Sub

Step 5: 유저폼을 불러오는 프로시저 작성하기

(4) 마지막으로, 이 유저폼을 불어올 프로시저를 작성하고 이것을 버튼에 연결하면 끝이 납니다.

Sub ShowForm()
    Dim Msg As String

    Msg = "죄송합니다" & vbCr
    Msg = Msg & "이 기능은 Excel 2000 버전부터 지원합니다"
    If Val(Application.Version) < 9 Then
        MsgBox Msg, vbCritical, "에러 발생//Exceller"
        Exit Sub
        '//Excel 2000 이하 버전일 경우에는 실행이 되지 않을 것이므로 Excel Version을 체크해서
        '//그 이하 버전이면 에러 메시지를 띄우고 프로시저를 빠져 나갑니다.

    Else
        UserForm1.Show vbModeless
        '//바로 요 부분입니다. 지금까지는 UserForm을 불러올 때, 그냥 UserForm.Show 이러한
        '//형태로 사용했습니다만, Modeless 형태로 호출하기 위해서는 Show 메서드 뒤에다가
        '//vbModeless라는 구문을 추가해 주면 됩니다.
        '//이 문장을 UserForm. Show 0 이렇게 적어도 됩니다.

    End If
End Sub

마무리

많이들 응용해 보시기 바랍니다. Have a Nice Weekend!!!

다음 시간에…

정리 — Modeless 대화상자 핵심

자주 묻는 질문 (FAQ)

마치며

Modeless 유저폼과 워크북 이벤트를 함께 쓰면 실시간으로 정보를 보여 주는 도구창을 만들 수 있습니다.