여러 시트의 데이터 비교하기

Step 1: 데이터 구조 살펴보기

TARGET 시트의 A열에는 거래처 코드, B열에는 거래처명이 있고 C열(SALES_01)과 D열(SALES_02)에 월별 실적을 채워 넣습니다. Sales_01, Sales_02 시트에는 각각 거래처 코드와 실적이 들어 있습니다(예제 시트에는 약 500건이 들어 있습니다).

작업 진행과정을 시각적으로 보여드리려고 이것저것 집어넣었기 때문에 작업속도는 좀 떨어집니다. 실제 여러분이 사용하실 때에는 이러한 요소들을 없애버리면 훨씬 빠르게 돌아갈 것입니다.

Step 2: 데이터 이전 코드 작성하기

Sub DataTransfer()
    Dim rngCell As Range
    Dim rngTarget As Range
    Dim rng01 As Range, rng01S As Range
    Dim rng02 As Range, rng02S As Range
    '//한 행에 두 개 이상의 변수를 선언해 줄 때에는 위와 같이 콤마로 구분하되 변수의 타입을
    '//명기해 주어야 합니다. 만약 이것을
    '//Dim rng01, rng01S as Range
    '//이렇게 하면 rng01S는 Range 오브젝트 변수로 선언이 되나 rng01은 Range Object가 아닌
    '//Variant형 변수로 선언이 되므로 주의하시기 바랍니다.

    Set rngTarget = Worksheets("target").Range("a:a").SpecialCells(xlTextValues)
    Set rng01S = Worksheets("Sales_01").Range("a:a").SpecialCells(xlTextValues)
    Set rng02S = Worksheets("Sales_02").Range("a:a").SpecialCells(xlTextValues)

    For Each rngCell In rngTarget
        For Each rng01 In rng01S
        '//이제부터 순환문을 돌면서 Target 시트의 거래처 코드와 Sales_01, Sales_02 시트의
        '//거래처 코드를 비교하여 코드가 같으면 자료를 옮겨줍니다.

            If rngCell = rng01 Then
            '//먼저 Target 시트의 거래처 코드와 Sales_01 시트 내의 거래처 코드들을 비교합니다.
            '//그래서 같은 것이 발견되면 Sales_01 시트의 해당값을 Target 시트에 옮겨 적은 다음,
            '//Exit For 문을 사용해서 순환문을 빠져 나갑니다.

                Application.DisplayStatusBar = True
                rngCell.Offset(0, 2) = rng01.Offset(0, 1)
                Application.StatusBar = "TARGET: " & rngCell.Offset(0, 2) & "/Sales_01: " & _
                    rng01.Offset(0, 1)
                Exit For
            End If
        Next rng01

        For Each rng02 In rng02S
        '//이번에는 Target 시트의 거래처 코드와 Sales_02 시트 내의 거래처 코드들을 비교해서
        '//같은 것이 발견되면, Target 시트에 그 값을 기재하고 역시 Exit For문을를 사용해서
        '//For~Next 반복문을 빠져나갑니다.

            If rngCell = rng02 Then
                Application.DisplayStatusBar = True
                rngCell.Offset(0, 3) = rng02.Offset(0, 1)
                Application.StatusBar = "TARGET: " & rngCell.Offset(0, 3) & "/Sales_02: " & _
                    rng02.Offset(0, 1)
                Exit For
            End If
        Next rng02

    Next rngCell
    Application.StatusBar = ""
    MsgBox "Data Transferring 작업이 끝났습니다", , "작업 완료//Exceller"
End Sub

숙제

몇 개의 시트라도 이런 식으로 가능할 것입니다. 이 코드를 보니까 어떤 생각이 드십니까? 혹시 VB0038 강좌에서 설명드린 "여러 시트 내용을 한 시트로 합치기" 강좌보다 쉽다는 생각이 드는 분이 있으시지요? 그런 생각이 드는 분은 자기자신도 모르게 실력이 일취월장하신 분입니다.

만약 그런 분들은 이 코드를 수정해 보시기 바랍니다. 어떻게? 오늘 강좌는 쉽게 설명을 드리기 위해 TARGET 시트에 있는 거래처 코드와 각 월별 시트에 있는 그것이 서로 같습니다. 그런데 경우에 따라서는 1월에는 있던 거래처가 폐쇄되어 2월에는 실적이 없을 수도 있고, 반대로 2월에 신설된 거래처의 경우에는 1월에 실적이 없을 수도 있겠지요? 이러한 경우를 체크할 수 있는 코드를 직접 만들어 보시기 바랍니다. 그다지 어렵지는 않을 것입니다.

마무리

어느덧 10월의 마지막 밤… 아니 날이군요. ^___^ 잘들 보내시고 11월에도 변함없이 의미있는 날들이 되시기를 바랍니다.

다음 시간에…

정리 — 여러 시트 데이터 비교 핵심

자주 묻는 질문 (FAQ)

마치며

원리를 이해하면 몇 개의 시트라도 같은 방식으로 데이터를 비교해 옮길 수 있습니다.