auto_open과 256 Column보다 큰 텍스트 파일 불러오기

질문 2: 256열보다 큰 데이터 불러오기

예제로 사용될 텍스트 파일 예제를 하나 만들어야 하니까 아래의 버튼을 누르세요. 순서대로 안하고 이것저것 누르며 에러가 나니까 반드시 순서대로 하시기 바랍니다.

그리고 모듈을 사용해서 텍스트 파일을 읽어오는 것이기 때문에 보통 "파일-열기" 메뉴를 사용했을 때보다 속도가 좀 느립니다. 버튼을 누르고 차나 한잔 하고 오시기 바랍니다. 이렇게 좋은 가을날 밤, 키보드나 두들기고 있는 Exceller의 노고에 경의를 표하면서… (농담입니다. 하하하!!!) 근데 청량한 밤공기가 너무도 좋군요!!!

예제 텍스트 파일(300개 필드가 있는 LongText.txt)을 만드는 코드는 아래와 같습니다(20행 × 300열의 숫자를 콤마로 구분해 기록합니다).

Sub MakeLongText()
    Dim r As Long
    Dim c As Integer
    Open ThisWorkbook.Path & "\LongText.txt" For Output As #1
    For r = 1 To 20
        For c = 1 To 300
            If c <> 300 Then
                Write #1, r * c;
            Else
                Write #1, r * c
            End If
        Next c
    Next r
    Close #1
    MsgBox "LongText.txt 파일이 생성되었습니다", , "파일 생성//Exceller"
End Sub

정상적으로 파일 생성 완료 메시지 박스가 나타났습니까? 그렇다면 이제 이 파일이 어떻게 생겼는지 텍스트 에디터(워드패드나 울트라 에디터, 텍스트 패드 등…)를 실행시킨 다음, 현재 이 강좌파일과 같은 폴더 밑에 있는 "LongText.txt" 파일을 열어서 살펴보시기 바랍니다. 분명히 필드가 300개가 있는지 한번 확인해 보세요.

확인하셨으면 이것을 워크시트 상에 불러와 보도록 하겠습니다. 만약 이 Text 파일을 문자열 마법사를 통해 불러오면 256열 까지만 Importing 되고 나머지는 읽어들이지를 못합니다.

어떻습니까? 1~256열까지의 자료는 Sheet1에 저장이 되고 나머지 257~300열까지의 자료들은 Sheet2에 차곡차곡 저장이 되지요? 코드를 보도록 하겠습니다.

Sub ImportLongFile()
    Dim rngImport As Range
    Dim i As Integer
    Dim intSheets As Integer
    Dim intLine As Long
    Dim r As Long
    Dim c As Integer
    Dim strData As String
    Dim strChar As String
    Dim strText As String

    intSheets = Application.SheetsInNewWorkbook
    Application.SheetsInNewWorkbook = 2
    Workbooks.Add
    Application.SheetsInNewWorkbook = intSheets
    '//여기까지는 시트를 2개 가진 새로운 워크북을 하나 만들기 위한 과정입니다.

    Open ThisWorkbook.Path & "\LongText.txt" For Input As #1
    Set rngImport = ActiveWorkbook.Sheets(1).Range("A1")
    Application.DisplayStatusBar = True
    Application.ScreenUpdating = False
    '//시간이 좀 걸리니까 화면갱신을 False로 지정했습니다. 즉 화면을 갱신하지 않습니다.

    Do While Not EOF(1)
        intLine = intLine + 1
        Line Input #1, strData
        Application.StatusBar = intLine & " Record Importing..."
        '//Line Input Statement에 의해 텍스트 파일을 한 라인씩 읽어들입니다. 그럴 때마다
        '//현재 몇 라인을 Importing 했는지를 상태표시줄에 나타냅니다.

        For i = 1 To Len(strData)
            strChar = Mid(strData, i, 1)
            '//이제 라인 내의 각 문자열 값을 strChar 변수에 저장한 다음 순환문을 돌면서
            '//여러 가지 조건분기를 시작합니다.

            If c = 256 Then
                c = 0
                Set rngImport = ActiveWorkbook.Sheets(2).Range("A1")
            End If
            '//만약 256열 이상이면 현재 워크북 두번째 시트의 A1 셀을 rngImport 오브젝트 변수에
            '//저장합니다.

            If strChar <> "," And strChar <> Chr(34) Then strText = strText & strChar
            If strChar = "," Or i = Len(strData) Then
                rngImport.Offset(r, c) = strText
                c = c + 1
                strText = ""
            End If
            '//strChar의 값이 콤마이거나 맨 끝 문자일 경우에는 해당 셀에 strText값을 뿌려주고
            '//필요한 변수값을 변화시킵니다. 여기서 strTemp는 콤마나 인용부호가 아닌 보통의
            '//문자열인 경우 해당 값을 계속 누적시켜 놓은 임시 문자열 변수입니다.

            '//그리고 strChar 변수값이 Chr(34), 즉 " 이 아닐 경우에는 strText 변수에 그 값을
            '//계속 담아둡니다.

        Next i
        c = 0
        r = r + 1
        Set rngImport = ActiveWorkbook.Sheets(1).Range("A1")
    Loop

    Close #1
    Application.ScreenUpdating = True
    Application.StatusBar = ""
    '//작업이 끝났으면 Open했던 파일을 닫고 ScreenUpdating 속성을 다시 True로 돌립니다.

End Sub

숙제

오래간만에 숙제를 하나 내 드릴까요? 열 방향으로 256열 보다 큰 자료를 불러오는 방법에 대해 이제 아셨으니까 이것을 응용해서 65536행 보다 큰 자료를 Importing하는 코드를 한번 만들어 보세요. 기본적인 논리는 비슷하니까 조금만 응용하시면 될 것입니다.

마무리

다음 시간에 또…

정리 — 256열 초과 불러오기 핵심

자주 묻는 질문 (FAQ)

마치며

열 방향으로 나누어 불러오는 방법을 익혔다면 행 방향으로도 같은 원리를 응용할 수 있습니다.