체크 표시하기

Step 1: 프로그램 구성

이 프로그램은,

• (1) 난수를 발생시키는 부분
• (2) 평균이상인 셀에 서식을 지정하는 부분

이렇게 나누어서 작성을 하는 것이 여러 모로 편리합니다.

Step 2: 난수를 발생시키는 프로시저

Sub MakeRandomNumber()
'//지정된 범위에 난수를 발생시키는 프로시저
    Dim i As Integer
    Dim intNum As Integer
    Dim rngCell As Range
    Dim rngAll As Range
    Dim obj As Object

    Set rngAll = Selection
    rngAll.Clear
    '//선택된 영역을 rngAll이라고 지정을 해 준 다음, 그 내부를 모두 지웁니다. Clear 메서드는
    '//ClearContents와 ClearFormats가 합쳐진 메서드라고 생각하시면 됩니다.

    For Each obj In ActiveSheet.DrawingObjects
        If TypeName(obj) = "Drawing" Then obj.Delete
        '//TypeName은 변수에 대한 정보를 알려줍니다. TypeName(obj) 라고 하면 선택된
        '//오브젝트가 어떤 것인지를 되돌려 줍니다. 따라서 현재 시트 내의 각종 Objects 중에서
        '//타입이 Drawing이면 그 오브젝트를 지우라는 것이 되지요.
    Next obj

    For Each rngCell In rngAll
        intNum = intNum + 1
        For i = 1 To 20
            With rngCell
                .Interior.ColorIndex = xlNone
                .Formula = "=rand()*100"
            End With
        '//이제 선택된 범위 내의 각 셀에다가 원하는 작업을 하는 것입니다. 먼저, 셀 내부에 이미
        '//색깔이 입혀져 있으면 없애주고(xlNone), rand() 함수를 써서 난수를 발생시킵니다.
        '//순환문을 또 한번 더 써준 것은… 그냥 시각적인 효과를 위해서입니다 ^^.
        Next i
    Next rngCell

    With rngAll
        .Copy
        .Cells(1).Select
        Selection.PasteSpecial Paste:=xlValues
        '//셀에 rand() 함수로 발생된 값을 그냥 그대로 두면 수시로 재계산되므로 공식을 없애고
        '//해당 셀의 값으로 치환해 주는 과정입니다.
    End With
    Call CheckMark
    '//평균값을 상회하는 셀에 표시를 해주기 위해서 다른 프로시저를 불러옵니다.
    '//여기서 Call이라는 문장을 사용했는데 이것은 생략하고 그냥 CheckMark라고만 해도
    '//상관없습니다. 예전에 BASIC을 배울 때(Visual Basic말고) 버릇이 남아 있는 것입니다.
    '//이것은 외부 프로시저를 불러올 때 사용하는 것입니다. 제 경우에는 이것이 보기에
    '//더 좋더군요. 어떻게 사용할 것인지는 여러분이 판단하실 일!
    rngAll.Cells(1).Select
End Sub

Step 3: 체크마크와 셀 색상을 입히는 프로시저

이제 두 번째 프로시저인 셀에 체크마크와 셀 색상을 입히는 프로시저입니다.

Sub CheckMark()
    Dim rngCell As Range
    Dim rngAll As Range
    Dim intAver As Integer
    Dim intCount As Integer

    Set rngAll = Selection
    intAver = Application.Average(rngAll)
    '//Average 함수는 Excel 내장함수입니다. 이것을 VBA에서 불러와서 사용하려면 위와 같이
    '//Application 또는 Application.WorksheetFunction을 붙이면 됩니다.

    MsgBox "선택된 영역의 평균값은 " & intAver & " 입니다" & _
        vbCr & "지금부터 해당 셀에 표시를 합니다", , "//Exceller"

    For Each rngCell In rngAll
        If rngCell.Value >= intAver Then
            intCount = intCount + 1
            With rngCell
                .Interior.ColorIndex = 22
                ActiveSheet.Drawings.Add(.Left, .Top, _
                    .Left + 10, .Top + 10, False).Select
                '//지정한 범위 내에서 평균값 이상인 셀에 대해 사선을 그리는 부분입니다.
                '//Drawing Object의 좌표 지정하는 방법은 예전에 사각형 그릴 때의 그것과 같으므로
                '//VB0002, VB0003 강좌를 참고하시기 바랍니다.

                '//간단하게 다시 한번 설명을 드리자면,
                '//ActiveSheet.Drawings.Add(ActiveCell.Left, ActiveCell.Top,ActiveCell.Left+10,
                '//, ActiveCell.Top+10)에서

                '//ActiveCell.Left는 현재 셀의 왼쪽 좌표, ActiveCell.Top은 현재 셀의 윗부분의 좌표,
                '//ActiveCell.Left+10은 현재 셀 왼쪽부분에서 10포인트 오른쪽으로 이동한 곳의 위치,
                '//ActiveCell.Top+10은 현재 셀 윗부분에서 10포인트만큼 아래로 이동한 곳의 위치를
                '//각각 나타냅니다. 따라서 사선이 한 줄 그어지게 되는 것이지요.

                With Selection
                    .AddVertex rngCell.Left + 10, rngCell.Top
                    .Border.ColorIndex = 3
                    '//위에서 그은 사선에 연이어서 위로 세로줄을 한 줄 긋고, 색상을 3, 즉 빨간색으로
                    '//지정합니다. ColorIndex의 색상에 대해서는 도움말이나 VB0036(PowerTools)
                    '//강좌 중에서 "색상 지정하기"를 참고하시기 바랍니다.
                End With
            End With
        End If
    Next rngCell
    MsgBox "평균값 이상인 셀은 모두 " & intCount & " 개 입니다" _
        , , "//Exceller"
End Sub

마무리

이상입니다. 별로 어려운 부분은 없는 것으로 생각됩니다만… 선을 그리는 방법은 잘 기억해 두시면 도움이 될 것입니다. 많이 응용해 보시기 바랍니다.

그럼…

정리 — 체크 표시 핵심

자주 묻는 질문 (FAQ)

마치며

선을 그리는 방법을 잘 기억해 두면 다양하게 응용할 수 있습니다.