작업중인 파일 삭제하기

Step 1: 결과 미리 보기

일단 아래의 버튼을 누르세요. 현재 강좌파일이 있는 경로에 KillWorkbook.xls라는 파일이 하나 만들어 질 것입니다. 그러면 "도구-매크로-매크로" 메뉴를 선택한 다음, "KillActiveWorkbook" 프로시저를 선택합니다. 그러면 KillWorkbook.xls 파일이 활성화 된 상태임에도 불구하고 바로 삭제가 될 것입니다.

이번 시간에는 바로 이것을 만들어 보는 것입니다. 이 프로시저는 Personal.xls에 복사를 해두고 사용하시면 편리할 것입니다.

Step 2: 코드 살펴보기

잘 되시지요? 코드를 살펴보도록 하지요.

Sub KillActiveWorkbook()
    Dim wrkBook As Workbook
    Dim strFile As String
    Dim intResult As Integer
    Dim i As Integer
    '//변수를 먼저 선언합니다.

    Set wrkBook = ActiveWorkbook
    On Error GoTo kkk
    '//예전에 On Error Resume Next라는 것에 대해서는 소개를 해 드렸지요?
    '//만약 에러가 발생하면 잔소리 말고 그 다음 구문을 실행하라는 것이었지요.
    '//On Error GoTo kkk는 에러가 발생하면 kkk로 가라는 의미입니다.

    intResult = MsgBox(wrkBook.Name & " 파일을 완전히 삭제할까요?", vbYesNo, "//Exceller")
    '//Yes와 No, 두 개의 버튼을 가진 메시지 박스를 띄워서 사용자로 하여금 하나를
    '//선택하게 한 다음, 그 결과값을 intResult 변수에 담아둡니다. 그러면 담아서 뭐에
    '//쓸려고 하느냐? 아래 구문에서 vbYes이면, 즉 "예" 버튼이 클릭되었으면 그 아래
    '//명령을 실행하고 "아니오" 버튼을 선택하면 그냥 빠져 나가는 것입니다.

    If intResult = vbYes Then
        Application.DisplayAlerts = False
        strFile = wrkBook.Path & "\" & wrkBook.Name
        '//wrkBook.Path는 현재 활성화된 워크북(파일)의 경로를 의미합니다. 따라서
        '//strFile 변수에는 Active Workbook의 경로와 파일명이 저장이 되겠지요.

        i = Len(strFile)

        wrkBook.Close savechanges:=False
        '//현재 워크북을 닫되 변경된 내용이 있어도 저장하지 말라는 의미입니다. 삭제를
        '//할 파일인데 변경내용을 저장해봤자 소용이 없겠지요?

        If i <> 0 Then Kill strFile
    End If

kkk:
    Application.DisplayAlerts = True
    If Err <> 0 Then MsgBox Err.Description, , "Error 발생//Exceller"
    '//"Err<>0"라는 것은 어떤 "에러가 발생했을 경우"를 의미합니다. 다시 말하자면
    '//Err=0라는 것은 아무런 에러가 발생하지 않았다는 것을 의미하지요.
End Sub

마무리

오늘 설명드린 내용은 아주 짧은 코드이지만 상당히 유용한 기능이라고 생각됩니다. 많이 응용하시기 바랍니다. 그리고 응용을 하시다가 아주 그럴듯한 것을 만드시게 되면 꼭 Exceller에게 알려 주시기 바랍니다. 그래야 보다 많은 사람들이 공유를 할 수 있으니까 말입니다.

그럼…

정리 — 파일 삭제 핵심

자주 묻는 질문 (FAQ)

마치며

짧은 코드이지만 파일을 정리할 때 아주 유용하게 쓸 수 있는 기능입니다.