유저폼에 차트 표시하기

Step 1: 결과 미리 보기

본론으로 들어 갑니다. 아래의 버튼을 눌러 오늘 만들어 볼 예제를 실행시켜 보시기 바랍니다.

재미있지 않습니까? 불가능한 것처럼 여겨졌던 유저폼에 그래프를 표시할 뿐 아니라 마우스로 선택하기만 하면 막대/꺾은선/영역형 그래프가 자동으로 생성되고… 여러분들이 어떻게 응용을 하느냐에 따라 이보다 재미있는 것을 얼마든지 만드실 수 있을 것입니다.

이제 이것을 만드는 방법을 단계별로 설명을 드리겠습니다.

Step 2: 차트와 UserForm 준비하기

(1) 먼저, 아래와 같은 표를 가지고 그래프를 하나 만듭니다. 그래프는 막대, 꺾은선, 영역형 중 어느 것을 그려도 상관없으나 여기서는 막대그래프를 하나 그렸습니다.

(2) VB Editor를 실행시키고 유저폼을 하나 삽입한 다음, 아래와 같이 컨트롤들을 추가합니다. 다른 컨트롤은 아실 것이고… Image라는 새로운 컨트롤이 등장합니다.

아이엑셀러

Step 3: 코드 작성하기

(1) 초기화 이벤트

(3) 유저폼에서 컨트롤이 없는 빈 공간을 더블클릭한 다음, 이벤트 선택 상자에서 초기화 이벤트(Initialize)를 선택하고 아래의 코드를 삽입합니다.

Private Sub UserForm_Initialize()
    optColumn.Value = True
    '//optColumn은 옵션버튼 중에서 "막대형"의 이름입니다. 따라서 유저폼이 호출이 되면
    '//초기값으로 막대 그래프가 선택이 되도록 설정하는 것입니다.
End Sub

(2) 옵션버튼 클릭 이벤트

(4) Shift + <F7>키를 눌러 유저폼으로 돌아간 다음, 옵션버튼 중에서 "막대형"을 더블클릭하면 클릭 이벤트가 하나 생성되는데 여기에 해당 코드를 입력합니다.

Private Sub optColumn_Click()
    Call UpdateChart(xlColumnClustered)
    '//즉 이 옵션버튼을 클릭하면 UpdateChart라는 프로시저를 실행을 하는데, 이 때
    '//xlColumnClustered라는 값을 매개변수(parameter)로 함께 전달을 합니다.
End Sub

(5) 유저폼으로 돌아가서, 이번에는 "꺾은선형"을 더블클릭하고 다음과 같은 코드를 작성합니다.

Private Sub optLine_Click()
    Call UpdateChart(xlLineMarkers)
    '//(4)와 같은데 xlLineMarkers라는 값을 호출하는 프로시저에 전달한다는 점이 다릅니다.
End Sub

(6) 유저폼으로 가서, "영역형"을 더블클릭하고 필요한 코드를 입력합니다.

Private Sub optArea_Click()
    Call UpdateChart(xlAreaStacked)
    '//이번에는 xlAreasStacked를 전달하는군요.
End Sub

(3) UpdateChart 프로시저

(7) 이번에는 각 이벤트 프로시저에서 공통적으로 호출하는 UpdateChart 프로시저를 작성합니다. 이 부분이 오늘 강좌의 핵심입니다.

Private Sub UpdateChart(CType)
    '//프로시저를 실행할 때 Ctype라는 값을 받으면서 시작되었습니다.
    '//Ctype에는 어느 프로시저에서 호출을 하느냐에 따라 xlColumnClustered, xlLineMarkers,
    '//xlAreaStacked 중에서 하나가 지정이 될 것입니다.

    Dim cht As Chart
    Dim strFile As String

    Set cht = Sheets("Preface").ChartObjects(1).Chart
    '//cht 변수에 Preface시트에 있는 첫번째 차트를 담아 둡니다.

    cht.ChartType = CType
    strFile = ThisWorkbook.Path & Application.PathSeparator & "Temp.gif"
    '//차트 형태를 지정해 주고, strFile 변수에는 현재 파일이 있는 경로명\Temp.gif라는
    '//값(실제로는 파일 경로\파일명)이 저장됩니다.

    cht.Export Filename:=strFile, filtername:="GIF"
    Image1.Picture = LoadPicture(strFile)
    '//현재 차트를 GIF 형태의 그림파일로 내보냅니다.
    '//그런 다음에 Image1 컨트롤로 다시 Loading, 즉 불러들이는 것입니다. 다시 말해서 차트를
    '//유저폼에 다가 바로 붙여넣을 수 없으니까 이것을 그림으로 만들어서 내보냈다가 이것을
    '//다시 불러다가 사용하는 것이지요.

End Sub

(4) 닫기 버튼과 폼 호출

Private Sub btnClose_Click()
    Unload Me
End Sub

Sub ShowChartForm()
    UserForm1.Show
End Sub

마무리

엄청 간단하지 않습니까? ^^

정말이지 다른 랭귀지로 이런 것을 하나 만든다고 생각을 해 보세요. 머리카락이 한 웅큼은 빠질 것입니다. 예전에 Exceller가 C(Visual C말고…)를 맛배기로 배울 때에는 이런 것은 상상 속에서나 존재했었습니다. 지금의 Visual C++은 어떤지 잘 알 수는 없지만 아마 그래도 여전히 어려울 것으로 생각됩니다.

많이들 응용해 보시기 바랍니다.

그럼…

정리 — 유저폼 차트 표시 핵심

자주 묻는 질문 (FAQ)

마치며

차트를 그림으로 바꾸어 불러오는 간단한 아이디어로 유저폼에서도 차트를 보여 줄 수 있습니다.