폴더 내의 모든 파일 한번에 출력하기

Step 1: 결과 미리 보기

아래의 버튼을 누른 다음 Excel 파일이 있는 아무 폴더나 입력해 보세요.

실제 작업을 하실 때에는 폴더를 하나 만든 다음 출력하고자 하는 (Excel)파일들을 이 폴더에 복사를 하 고 이 버튼을 클릭하면 폴더 내의 모든 Excel파일, 시트들이 순차적으로 출력됩니다.

옛날 이야기 하나

Exceller가 처음 회사에 들어왔을 때 사무실의 컴퓨팅 환경은 486SX급 PC에 Dot Matrix 프린터를 쓰고 인터넷은 14400BPS 모뎀을 통해 정말 참을 인자 수십 개씩 써가며 간혹 접속되는 말 그대로 아주 열악 한 그런 환경이었습니다. 그 당시에는 그런 것을 몰랐었지만…

컴퓨터는 그런 대로 1인 1PC 상태였으니(그나마 다른 부서보다 앞서서…) 괜찮았는데 프린터가 문제였 습니다. 보통 4~5인이 프린터를 공유해서 사용을 하다 보니 특히 더 그랬습니다. 많은 자료를 출력할 때 직접적으로 눈치를 주는 사람은 없었으나 "아직 많이 남았어?" 또는 "뭐 출력해?"하고 한 마디씩 하고 갈 때마다 적지 않게 부담이 되었습니다. 가장 여유있는 시간은 점심시간이나 남들이 다 퇴근한 저녁시간 이었지요.

그 때 오늘 설명드린 VBA를 알았더라면… 하긴 그 때는 VBA는 고사하고 Excel이 뭔지도 모를 때였었지요. 도스용 Lotus를 쓰던 시절이었으니까.

하여튼 그 때와 비교를 하면 지금은 엄청나게 좋아진 환경임에는 틀림없습니다만 아직도 출력을 할 때, 눈치를 보는 분이 혹시 있으신지 모르겠군요. 또는 굳이 그것 때문이 아니라 그냥 허비하기 쉬운 점심식 사 시간에 시간이 많이 걸리는 프린팅 작업을 하고 점심시간이 끝나면 바로 출력물로 다른 분석작업 등 에 들어갈 수 있으니 훨씬 효율적인 업무진행이 되겠지요?

말이 많아졌군요. ^^ 코드를 살펴보도록 하지요.

Step 2: 코드 작성하기

Sub PrintAllFiles()
    Dim sht As Worksheet
    Dim strDir As String
    Dim strFile As String
    strDir = Trim(InputBox("출력 폴더를 입력하세요: ", "http://www.iexceller.com"))
    '//변수를 선언한 다음 출력 대상 폴더를 사용자로부터 입력받는 과정입니다.
    '//다른 것은 아실테고… InputBox를 통해 폴더명에 입력받을 때 Trim() 함수를 함께 사용했군요.
    '//왜 그랬을까요? 사용자가 입력하면서 혹시 문자열 앞뒤에 공백을 집어넣을 경우 에러처리를 해
    '//주기 위함입니다.

    If Right(strDir, 1) <> "\" Then strDir = strDir & "\"
    strFile = Dir(strDir & "*.xls")
    '//이 부분은 지난 시간에도 설명을 드린 것 같은데, Dir() 함수를 써서 폴더를 검색할 때 폴더명 뒤에
    '//반드시 \표시를 붙여주어야 합니다. 그런데 대개의 사용자들은 이것을 입력하지 않을 것입니다.
    '//이런 경우 에러가 발생하게 되므로 사용자가 입력한 문자열의 마지막 1문자를 검색해서 \로 끝나
    '//지 않았으면 \를 추가해 줍니다.

    '//그런 다음에 strFile이라는 변수에는 디렉토리명과 그 디렉토리에 있는 첫번째 Excel 파일명을 담
    '//아 둡니다.

    If strFile = "" Then
        MsgBox "아무 Excel 파일도 없습니다", , "http://www.iexceller.com"
        Exit Sub
        '//폴더 내에 Excel 파일이 하나도 없으면 에러 메시지를 뿌려주고 프로시저를 종료합니다.
    End If

    Do
    '//이제 Do~Loop 순환문을 돌면서 폴더 내의 모든 Excel 파일들을 검색합니다.

        Workbooks.Open strDir & strFile
        For Each sht In Worksheets
            sht.PrintPreview
            '//오픈된 Excel 파일의 모든 워크시트를 미리보기(PrintPreview) 합니다. 만약에 미리보기가
            '//아니라 바로 프린터로 출력을 하고자 한다면 PrintPreview를 PrintOut으로 고쳐주시면 되겠
            '//지요?

        Next sht

        ActiveWorkbook.Close
        strFile = Dir()
        '//모든 워크시트에 대한 출력작업이 끝났으면 Close 메서드를 통해 활성화된 워크북을 닫습니다.
        '//그 다음에 strFile=Dir()이라고 한 것은 어떤 기능을 수행하지요? 그렇습니다. 지난 시간에 설명
        '//을 드린대로 좀전에 출력했던 그 다음의 파일을 자동으로 저장하게 됩니다.

    Loop Until strFile = ""
    '//strFile변수의 값이 공백이 될 때까지, 그러니까 해당 폴더내에 ".xls"파일이 없을 때까지 계속 루핑
    '//을 하게 되겠군요.
End Sub

마무리

코드는 몇 줄 안되지만 거기에 비하면 아주 강력한(?) 기능이지요?

다음 시간에 또…

정리 — 일괄 출력 핵심

자주 묻는 질문 (FAQ)

마치며

몇 줄의 코드로 점심시간 동안 폴더 안의 모든 파일을 출력해 두는 강력한 자동화를 만들 수 있습니다.