파일 검색하기

Step 1: 파일 목록 만들기 코드

Sub ShowFileList()
    Dim sht As Worksheet
    Dim intRow As Integer
    Dim strDir As String
    Dim strFile As String
    '//필요한 변수를 먼저 선언합니다.

    Set sht = ActiveSheet
    strDir = Trim(InputBox("검색할 폴더명을 입력하세요: ", "http://www.iexceller.com"))
    intRow = 1
    '//sht라는 변수에 ActiveSheet, 즉 현재 시트를 저장해 둡니다. 그리고 InputBox 함수를 사용해서
    '//어떤 폴더를 출력할 지 사용자가 직접 입력을 하도록 합니다. 여기서 Trim() 함수를 사용해 준 것
    '//은 무엇 때문일까요? 그렇습니다! 혹시 입력하는 사람이 좌우에 공백을 입력할 경우 에러를 방지
    '//하기 위한 것입니다.

    Worksheets.Add after:=Sheets("Preface")
    If Right(strDir, 1) <> "\" Then strDir = strDir & "\"
    '//Preface 시트 뒤에 새로운 워크시트를 한 장 삽입하고, InputBox를 통해 입력받은 strDir의 값의
    '//마지막이 \로 끝나지 않았으면 \를 첨가합니다. Dir() 함수를 사용할 때 마지막 부분에 \이 없
    '//으면 에러가 발생하므로 미리 이 경우에 대비를 하기 위한 것이지요.

    strFile = Dir(strDir)
    If strFile = "" Then
        MsgBox "해당 폴더에 파일이 없습니다", , "http://www.iexceller.com"
        Exit Sub
    End If
    '//strDir 폴더 내에 있는 첫번째 파일명을 strFile 변수에 저장합니다.

    Cells(intRow, 1) = "파일명"
    Cells(intRow, 2) = "크기"
    Cells(intRow, 3) = "작성일자"
    Range("a1:c1").Font.Name = "HY견고딕"

    intRow = intRow + 1
    Cells(intRow, 1) = strFile
    Cells(intRow, 2) = FileLen(strDir & strFile)
    Cells(intRow, 3) = FileDateTime(strDir & strFile)

    Do While strFile <> ""
        strFile = Dir()
        '//이제 Do~Loop 순환문을 돌면서 파일들에 대한 정보들을 워크시트 내에 차례로 뿌려줍니다.
        '//여기서 strFile=Dir() 이라고 해 주면 자동으로 다음에 위치한 항목, 즉 다음 파일을 차례로 읽어
        '//들이게 됩니다.

        If strFile <> "" Then
            intRow = intRow + 1
            Cells(intRow, 1) = strFile
            Cells(intRow, 2) = FileLen(strDir & strFile)
            Cells(intRow, 3) = FileDateTime(strDir & strFile)
        End If
    Loop

    Range("a2").Select
    Selection.Sort Key1:=Range("a2"), Header:=xlGuess, order1:=xlAscending
    Columns("a:c").EntireColumn.AutoFit
    '//시트 상의 내용들에 대해 Sorting을 한 다음, 열 폭을 맞추어 줍니다.

    MsgBox "총 " & intRow - 1 & " 개의 파일이 발견되었습니다", , "http://www.iexceller.com"
End Sub

정리

이상의 방법이 Dir() 함수를 사용하는 일반적인 방법입니다. 즉 처음 Dir 함수를 사용할 때에는 Dir("c:\windows\")와 같은 형태로 해서 폴더를 지정해 주고 그 다음번에는 그냥 Dir() 이라고만 하게 되면 자동으로 다음 해당 파일을 읽어들이는 것이지요.

마무리

다음 시간에는 이 Dir() 함수를 이용한 아주 실용적인 예제 한 가지에 대해 설명을 드리도록 하겠습니다. 도움말에 있는 Dir() 함수의 활용예제에 대해 미리 한번씩 읽어두시기 바랍니다.

오늘은 여기까지…

정리 — Dir 함수 파일 검색 핵심

자주 묻는 질문 (FAQ)

마치며

Dir 함수의 첫 호출과 이후 호출의 차이만 이해하면 파일 검색은 어렵지 않습니다.