Class Module 사용하기

Step 1: 결과 미리 보기

무슨 프로그램을 만들어 볼려는지 아시겠지요? 버튼을 클릭하니까 수십 개의 버튼이 달린 유저폼이 하나 나타납니다. 그리고 각각의 버튼을 다시 클릭하게 되면 "몇 번째 버튼이 클릭되었는지, 그 버튼의 유저폼 상에서의 좌표" 등에 대한 정보를 화면상에 표시하는 그런 프로그램입니다.

코드를 보시기 전에… 어떻게 프로그래밍을 했을지 생각해 보시기 바랍니다. 버튼을 몇십 개 만든다음에 각 버튼에 대한 코드를 모두 하나씩 코딩을 했을까요? 물론 시간이 팡팡 남아도 는 용감한(?) 사람이라면 그렇게 할 수도 있을 것입니다. 하지만 엄청난 인내를 요하는 작업이 되겠지요?

Today's Sample은 클래스 모듈을 사용한 것입니다.

Step 2: 클래스 모듈이란?

Class Module이란 용어를 들어 보셨는지? 아마 많은 분들이 처음 접해보시리라 생각합니다. 클래스 모듈을 잘 이해하시면 여러분의 내공은 또 한 단계 상승할 것입니다. 잘 익혀 두시기 바랍니다.

클래스 모듈은 모듈은 모듈인데 좀 특수한 형태의 것입니다. 지금까지는 두 가지 종류의 모듈을 사용해서 프로그램을 작성해 왔었습니다. 일반 VBA 모듈(general VBA module)과 코드 모듈(code module for VBA) 이 그것이었지요? 클래스 모듈이 VBA에 도입된 것은 Excel 97 버전부터인 것으로 기억이 됩니다.

클래스 모듈이란 "프로그래머로 하여금 새로운 오브젝트 클래스를 만들도록 해 주는 것" 이라고 할 수 있겠습니다(물론 그렇다고 해서 지금까지 존재하지 않던 그런 새로운 것이라는 뜻은 아닙니다).

쉽게 설명을 드리자면... 국화빵을 만들 때 빵틀과 국화빵의 관계를 잘 생각해 보시면 되겠군요. 국화빵 장수가 빵을 만들 때 사용하는 빵틀이 클래스 오브젝트의 역할을 수행한다고 생각하시기 바랍니다. 빵틀을 한번만 만들어 두면 열 번이고 스무 번이고 계속해서 같은 모양의 것을 생산해 낼 수가 있겠지요.

자, 그러면 국화빵틀을… 아니 클래스 모듈을 한번 만들어 보도록 하겠습니다.

Step 3: 유저폼과 클래스 모듈 만들기

(1) UserForm을 하나 삽입을 한 다음 아래와 같이 컨트롤들을 삽입합니다.예고한 바와 같이 각 컨트롤에 대한 상세한 설명은 생략합니다.

아이엑셀러

(1) 클래스 모듈 작성

(2) VB Editor 상태에서 현재의 프로젝트에다가 클래스 모듈을 하나 삽입합니다. 프로젝트라고 하니까 '프 로젝트는 또 뭐야?' 하시는 분이 있으실지 모르겠는데 그냥 파일(워크북)이라고 생각하세요. 클래스 모듈이 삽입되었으면 이름을 Class1에서 "MyButtonClass"로 고쳐 줍니다. 이름은 어떻게 바꾸느냐 고요? 속성창에서(만약 속성창이 없으면 <F4>키를 눌러 보세요) 이름 속성을 바꾸어 주시면 됩니다.

클래스 모듈시트에 아래의 코드를 입력합니다.

Option Explicit
Public WithEvents MyGroup As MSForms.CommandButton
'Public이라는 새로운 것이 하나 나왔군요. 지금까지는 변수를 선언할 때 주로 Dim문을 사용했습니다.
'Dim문을 통해 변수를 정의하면 해당 프로시저 내에서만 사용을 할 수 있습니다(물론 모듈 도입부에
'사용하면 달라지긴 하지만…)
'Public으로 변수를 선언하면 (현재) 모듈 전체에서 그 변수를 (매번 선언하지 않아도) 사용할 수가 있게
'됩니다.

'만약 커맨드 버튼이 아니라 옵션 버튼에 대해 설정을 하고 싶다고 할 경우, Public WithEvents 선언을
'다음과 같이 바꾸어 주면 됩니다.
'Public WithEvents MyGroup As MSForms.OptionButton

Private Sub MyGroup_Click()
'아래 부분은 MyGroup의 클릭 이벤트에 대한 코드인데 별로 어려운 부분은 없을 것입니다.

    Dim Msg As String

    Const ID = "//Exceller"
    Msg = MyGroup.Caption & " 번 버튼을 선택하셨습니다." & vbCr & vbCr
    Msg = Msg & "버튼의 좌표는" & vbCr & vbCr
    Msg = Msg & "위에서부터 " & MyGroup.Top & "," & vbCr
    Msg = Msg & "왼쪽에서부터 " & MyGroup.Left & vbCr & vbCr
    Msg = Msg & "입니다."

    If Err <> 0 Then
        MsgBox "에러가 발생하였습니다.", , ID
        Exit Sub
    Else
        MsgBox Msg, vbInformation, ID
    End If
End Sub

(2) 유저폼 호출 프로시저

(3) 일반 VBA 모듈(general VBA module)을 하나 삽입한 다음, 유저폼을 호출하기 위한 코드를 작성합니다.

Sub ShowUserForm()
    UserForm1.Show
End Sub

(3) 유저폼 초기화 이벤트

(4) UserForm1을 불러낸 다음, 유저폼의 컨트롤이 없는 빈 공간을 더블클릭하여 코드 모듈이 나타나도록 합니다. 그 다음에 이벤트 선택상자에서 초기화 이벤트(Initialize)를 발생시키고 아래의 코드를 작성합니다.

Option Explicit
Option Base 1
Dim MyButtons() As New MyButtonClass
'먼저, MyButtons()라는 오브젝트 배열(Object Array)을 하나 선언을 합니다.

Private Sub UserForm_Initialize()
    Dim ctl As Control
    Dim intCount As Integer
    '필요한 변수를 미리 선언 해두고…

    For Each ctl In UserForm1.Controls
    '유저폼 내의 모든 컨트롤들을 대상으로 작업을 하되 "CommandButton"인 경우에만 If~EndIf 구문 내의
    '작업을 수행합니다.

        If TypeName(ctl) = "CommandButton" Then
            If ctl.Name <> "btnClose" Then
                intCount = intCount + 1
                ctl.Caption = intCount
                ReDim Preserve MyButtons(intCount)
                'ReDim문은 아실테고… Preserve라는 것은 사전적인 의미로는 "보존하다, 유지하다" 뭐 이런
                '뜻일 것입니다. 즉 "동적 배열변수의 저장공간을 재할당"하는 명령입니다. 다시 말해서 배열의
                '마지막 차원의 길이를 변경하고자 할 때, 동적배열에 이미 담겨져 있는 기존 자료를 보존하기
                '위한 명령입니다.

                '어떤 업무를 할 때 "이 일이 과연 할 필요가 있는 일인가?"하는 의구심이 들 때, 여러분은 어떻게
                '하십니까?" 그런 생각이 들면 그 일을 한번 하지 말아 보십시오. 그러다가 일정 시간이 지난 다음
                '에 누군가가 그 일(또는 결과물)을 다시 찾게 되면 필요한 일이고 그렇지 않으면 불필요한 일이
                '겠지요 ^^.

                '프로그래밍도 마찬가지입니다. Preserve라는 명령어가 무슨 역할을 수행하는지 궁금하시면
                '이것을 생략하고 프로그램을 실행시켜 보시면 되겠지요? 그래서 제대로 돌아가면 불필요한 것
                '이고 문제가 생기면 꼭 필요한 요소라 할 수 있을 것입니다.

                Set MyButtons(intCount).MyGroup = ctl
            End If
        End If
    Next ctl
End Sub

Private Sub btnClose_Click()
    Unload Me
End Sub

마무리

이렇게 하시면 됩니다. 이제 클래스 모듈이 무엇이고, 어떨 때 사용할 수 있는 것인지 아시겠습니까? 처음 볼 때 잘 이해가 안되면 일단 덮어두었다가 한 달쯤 지난 뒤에 다시 보시기 바랍니다. 서두에 말씀드린 바와 같이, 오늘 강좌를 이해하시면 공력이 한단계 올라갈 것입니다.

다음 시간에 또…

정리 — 클래스 모듈 핵심

자주 묻는 질문 (FAQ)

마치며

처음에는 이해가 어려우면 일단 덮어 두었다가 한 달쯤 뒤에 다시 보시기 바랍니다.