유저폼 상에서의 중복아이템 추려내기

Step 1: 유저폼 만들기

(1) VB Editor 상태에서(Alt+<F11>) UserForm을 하나 삽입합니다. (2) 아래의 그림을 참조하여 유저폼에 예제와 같은 컨트롤 들을 삽입합니다.

아이엑셀러

(3) 각각의 속성을 다음과 같이 바꾸어 줍니다. 사용된 컨트롤은 세 종류(ListBox, CommmandButton, Label), 5개 입니다.

① Label 컨트롤

지금까지는 레이블 컨트롤의 캡션을 변경할 때 속성창에서 직접 바꾸어 주었는데 오늘은 프로그램 상의 코딩작업을 통해 변경하도록 하겠습니다.

② ListBox 컨트롤

리스트박스 컨트롤도 속성을 변경할 필요가 없습니다. 그냥 크기나 적당히 조절하시면 되겠습니다.

③ 명령버튼(CommandButton)

Step 2: 코드 작성하기

(1) OK 버튼

(4) 이제 각 컨트롤들에 대해 필요한 지능을 부여하는 작업을 해 주어야 겠지요? 먼저, OK 버튼을 더블클릭합니다. 그러면 Private Sub cmdOK_Click()이라는 이벤트가 나타나게 되는데 아래의 코드를 입력합니다. "복사-붙여 넣기"를 해도 되겠지만 가급적 직접 손으로 입력해 보는 것이 좋을 것입니다.

Private Sub cmdOK_Click()
    Dim intNum As Integer
    Dim str As String
    '//언제나 그렇듯이 변수를 지정해 줍니다.
    '//intNum은 리스트 박스 내에서 몇 번째 항목이 선택되었는지를 받기 위한 변수이고,
    '//str은 사용자에게 메시지를 보여주기 위한 변수입니다.

    With ListBox1
        intNum = .ListIndex
        If ListBox1.ListIndex < 0 Then
            MsgBox "메뉴를 선택하세요!!", vbInformation, "//Exceller"
            Exit Sub
            '//ListIndex 속성값은 항상 0부터 시작이 된다고 지난 번에 설명을 드렸는데 기억하고 계시지요?
            '//따라서 ListIndex 속성이 0보다 작다는 것은 아무 것도 선택되지 않았다는 것이니까 이런 경우
            '//에는 에러 메시지를 출력하고 프로시저를 빠져 나가도록 조치합니다.

            '//여기서 vbInformation이라는 못보던 것이 하나 나왔지요? 이것을 MsgBox 상수라고 부르며,
            '//vbOKOnly, vbYesNo, vbQuestion, vbExclamation, vbCritical 등 20여 가지가 있습니다. 또한
            '//두 개 이상의 상수들을 조합해서 vbExclamation + vbOKOnly 등과 같이 사용할 수도 있습니다.
            '//그 밖의 상수들에 대해서는 도움말을 참조하세요. 한 20여 가지 정도 될 것입니다.
        End If

        str = .List(intNum) & "을(를) 선택하셨군요!" & vbCr & vbCr & _
        "대단한 안목이십니다!!!"
        '//선택된 리스트 박스의 목록에 다가 다른 문자열 등을 첨가하여 새로운 문자열을 하나 만듭니다.
    End With
    MsgBox str, , "//Exceller"
End Sub

(2) 닫기 버튼

(5) Shift + <F7>을 눌러 유저폼을 불러온 다음, Cancel 버튼을 더블클릭 하여 코드창에 유저폼을 종료하기 위한 다음의 코드를 입력합니다. 이 코드는 이제 눈감고도(!) 입력하시겠지요?

Private Sub cmdClose_Click()
    Unload Me
End Sub

자, 이제 여기까지가 워밍업 이었습니다 ^^. 심호흡을 하시고… 계속 진행하도록 하지요.

(3) 컬렉션으로 중복 제거하기

(6) "삽입-모듈" 메뉴를 선택하여(또는 도구모음을 사용하셔도 되겠지요?) 모듈 시트를 하나 삽입합니다. 그 다음에 다음의 코드를 입력하세요. 이 부분이 오늘의 핵심입니다.

Sub ExtractOneItem2()
    '이 예제는 J.G. Hussey님의 아이디어에서 힌트를 얻어 만들어 본 것입니다//By Exceller
    Dim rngAll As Range
    Dim rngCell As Range
    Dim X As New Collection
    Dim varItem
    Dim sht As Worksheet
    '//등장인물과 배역을 지정해 주었습니다.
    '//rngAll은 아이템들이 있는 전체 영역을 지정하기 위한 Range 오브젝트 변수,
    '//rngCell은 rngAll 내에 있는 각 셀들에 접근하기 위한 오브젝트 변수입니다.
    '//그 다음에 Dim X As New Collection이라는 보도듣도 못한 새로운 것이 하나 나왔지요?
    '//이것이 바로 컬렉션 오브젝트 입니다. 이것을 통해 새로운 아이템들을 담아둘 수 있는데 아래에서
    '//설명을 드리겠습니다.

    Set sht = Sheets("Sheet2")
    Set rngAll = sht.Columns(1).SpecialCells(xlTextValues)
    '//sheet2를 sht라는 시트 오브젝트 변수에 담아두고, rngAll에는 sheet2의 1번째 열 중에서 문자열이
    '//들어있는 모든 셀이 포함이 됩니다. 즉 문자열이 연속되지 않아도 되는 것이지요.

    On Error Resume Next
    '//On Error Resume Next는 "에러가 발생했을 경우 계속해서 그 다음 문장을 실행하라"는 뜻이라는 건
    '//다들 아실테고… 한 가지 주의하셔야 할 점은, 오늘의 컬렉션 오브젝트를 사용하기 위해서는 이 구문
    '//을 반드시 적어주어야 한다는 것입니다. 그 이유는… 아래에서 설명드립니다.

    For Each rngCell In rngAll
        X.Add rngCell.Value, CStr(rngCell.Value)
        '//컬렉션 오브젝트의 기본적인 사용형태는
        '//[오브젝트명.Add Item, key, (before), (after)] 입니다.
        '//여기서 key 요소(정식 용어로는 argument라고 하지요)는 unique한 텍스트, 즉 중복되지 않는
        '//텍스트일 경우에만 유효합니다.
        '//먼 말이냐 하면, 만약에 위에서 나왔던 값을 밑에서 또 만나면 에러가 발생하게 되고, 따라서
        '//아이템에 추가가 되지 않는다는 말입니다. 이러한 성질머리를 최대한 활용해서 오늘의 과제를
        '//를 해결하는 것이지요.

        '//다시 한번 정리를 해 보면, key라는 argument가 사용되면 반복되는 값이 나타날 때 에러가 발생
        '//합니다. 에러가 발생되면 당연히(!) 아이템이 추가가 되지 않을 것입니다. 그렇지만 위에서 On
        '//Error Resume Next라는 구문을 써 주었으므로 프로그램 자체를 종료하지는 않고 그 다음 아이
        '//템을 계속 돌면서 새로운 아이템이 발견될 경우 이를 추가하게 되는 것이지요.

        '//즉, 에러가 발생되면 아이템이 추가가 되지 않지만 "이것이 바로 우리가 원하는 바"이지요. 기특
        '//하게도…

        '//이해 하시겠습니까?
    Next rngCell
    On Error GoTo 0

    UserForm1.ListBox1.Clear
    For Each varItem In X
        UserForm1.ListBox1.AddItem varItem
        '//컬렉션 오브젝트인 X에 저장된 아이템(들)에 대해 순환문을 돌려서 UserForm1에 있는 리스트
        '//박스에 아이템을 하나씩 하나씩 추가해 나갑니다.
    Next varItem

    With UserForm1
        .Label1.Caption = "발췌된 아이템數: " & X.Count
        .Label2.Caption = "총 아이템數: " & rngAll.Count
        .Show
        '//지금까지는 유저폼 내에 있는 레이블 컨트롤의 속성을 바꾸어 줄 때 속성창을 사용하여 수정을
        '//해 주었었지요? 그렇지만 이렇게 코딩을 통해 고쳐줄 수도 당연히 있습니다. 적어도 손으로 작업
        '//이 가능하다면 프로그래밍을 통해 자동화를 할 수 있다는 얘기가 되지요.
    End With
    '//이러한 일련의 과정을 통해 중복 아이템들이 걸러진 Unique한 Item들을 리스트 박스에 추가한 다음,
    '//이것을 유저폼의 Show 메서드(Method)에 의해 화면상에 표시합니다.
End Sub

마무리

이렇게 해주면 됩니다. 생각만큼 복잡하지는 않을 것입니다. 다음에 또…

정리 — Collection 중복 제거 핵심

자주 묻는 질문 (FAQ)

마치며

새로운 개념이 하나 나오니 차분히 따라 해 보시기 바랍니다.