중복아이템 추려내기

Step 1: 결과 미리 보기

이번 시간에 설명드릴 내용은 강좌 제목 그대로 '중복되는 아이템들 중에서 유일한 것만 발췌해 내는 방법'에 대한 것입니다. "그게 뭐야?" 하시는 분들은 위의 버튼을 눌러서 예제를 한번씩 실행시켜 보고 돌아오시기 바랍니다. 이런 질문을 해오신 분들이 그동안 몇분 있었는데 그 분들에게 답변해 드린 내용을 약간 수정해서 설 명을 드리도록 하지요.

Step 2: 고급 필터가 있는데 왜 코딩할까?

여러 아이템들 중에서 중복되지 않는 값들만 추려내는 가장 손쉬운 방법은 아마도 "고급 필터" 기능을 사용하는 것이겠지요? 혹시 '고급 필터에 그런 기능이 어딨어?' 하시는 분이 있으신지? 언젠가 말씀을 드렸던 것 같은데 VBA로 프로그래밍을 하기 이전에 엑셀 본연의 기능 중에 비슷하거나 같은 기능이 있나없나를 먼저 살펴보아야 합니다. 그러기 위해서는 엑셀의 모든 기능들을 속속들이 깨 야 하는 것이겠지요?

각설하고, "고급 필터" 메뉴 중에서 "고유 레코드만" 이라는 항목이 있는데 여기를 선택하고 고급 필터링 을 하게되면 중복없이 고유한 값들만 발췌가 됩니다. 그러면 이런 의문을 가지시겠지요? 즉,

"좀전에는 프로그래밍을 하기 전에 엑셀의 기능을 잘 살펴본 다음, 그런 기능이 없으면 코딩을 하라고 해 놓고, 이제는 왜 고급 필터에 그런 기능이 있단걸 알면서도 프로그램을 짜려 합니까?"

아주 예리한 질문이군요(^^)! 아래의 대표적인 두 가지 이유 때문이지요.

(1) 고급 필터 기능을 사용할 수 없는 상황에 처했을 경우에 대비하기 위해서 입니다. 예를 들어 어떤 프로 그램을 짜서 다른 사람들에게 배포를 했는데 프로그램만 실행시켰다 하면, "워크시트로 빠져 나가서 고급 필터 메뉴에서 고유 레코드만 추출시킨 다음, 다시 돌아오세요!" 뭐 이런 메시지가 나타난다면 프로그램을 공들여서 힘들게 만들어 주고도 욕얻어 먹기 딱 좋겠지요 ^^.

(2) 그리고 또 한가지 이유는 프로그래밍 하는 논리적인 사고를 배양하기 위해서입니다.

Step 3: 코드 살펴보기

코드에 대해 설명을 드리도록 하지요.

Private Sub CommandButton1_Click()
    '이 프로시저를 실행하기 전에 별도로 Sorting을 한다거나 하는 작업은 필요가 없습니다.
    Dim intNum As Integer
    Dim intNum1 As Integer
    Dim intNum2 As Integer
    Dim rngSource As Range
    Dim rngTarget As Range
    Dim strDefault As String
    Dim lngLast As Long
    Dim strActiveCell As String
    '늘 그래왔듯이 변수, 즉 등장인물을 지정합니다.

    Const str1 = "대상 영역의 첫 셀을 선택하세요." & vbCr & _
        "A2 셀을 선택하시는 것이 좋겠군요"
    Const str2 = "어느 셀에서부터 출력할까요?" & vbCr & _
        "B2 셀을 선택하세요!"
    'Const에 대해서는 설명을 드렸던가요? Dim은 변수를 선언할 때 사용하는 반면, Const는 변수가
    '아닌 상수를 지정할 때 쓰는 선언문입니다.

    strActiveCell = ActiveCell.Address
    strDefault = Range("a2").Address
    On Error Resume Next
    Set rngSource = Application.InputBox(str1, "대상셀 선택//Exceller", Type:=8)
    Set rngTarget = Application.InputBox(str2, "출력기준셀 선택//Exceller", strActiveCell, Type:=8)
    'Excel 함수인 InputBox() 함수를 써서 추출할 대상이 되는 셀과 추출한 다음 출력할 기준이 되는
    '셀의 위치를 지정합니다.

    If rngSource Is Nothing Or rngTarget Is Nothing Then Exit Sub
    '만약 실행도중 에러가 발생하더라도 계속 실행을 하라는 문장이지요?
    lngLast = rngSource.Parent.Cells(rngSource.Parent.Rows.Count, rngSource.Column).End(xlUp).Row - rngSource.Row

    For intNum = 0 To lngLast
    '여기서부터 이제 본격적인 중복자료 추출작업에 들어갑니다. rngSource.CurrentRegion.Rows.Count
    '이므로 추출할 대상이 되는 셀에 잇닿아 있는 주변 셀들의 행의 개수만큼 순환문이 반복되겠군요.

        For intNum1 = 0 To intNum - 1
            If rngSource.Offset(intNum, 0) = rngSource.Offset(intNum1, 0) Then GoTo et
            '그런 다음 또 한번의 For~Next 문을 사용해서 추출할 대상이 되는 셀이 한간씩 아래로 이동할 때
            '마다 바로 그 위의 셀들의 값을 일일이 비교를 하게 됩니다. 그래서 같은 값이 나오면 GoTo et 즉,
            'et 부분으로 이동합니다. 여기서 et는 아무 작업도 하지 않도록 설정해 준 하나의 분기점입니다.
            '비록 et에서는 아무 작업도 하지 않지만 일단 갔다가 돌아오면 intNum1은 값이 하나 증가하므로
            '그 아래 셀로 이동하여 비교를 하게 되겠지요?
        Next intNum1

        rngTarget.Offset(intNum2, 0) = rngSource.Offset(intNum, 0)
        '그래서 만약 위 셀의 값과 아래 셀의 값이 다르다면 그것은 새로운 아이템이므로 지정한 셀에 그 값을
        '뿌려주는 것이지요.

        intNum2 = intNum2 + 1
        '그 다음, intNum2의 값을 1씩 증가시켜 주었네요. 여기서 intNum2는 중복없이 아이템을 추출할 때마다
        '셀을 한간씩 아래로 이동시켜 출력하기 위한 변수입니다.

        Application.DisplayStatusBar = True
        Application.StatusBar = intNum2 & "개의 Item 추출..."
        If intNum2 > 15 Then ActiveWindow.SmallScroll down:=1
        '위 세 라인은 프로그램의 실행과는 직접적인 연관이 없이, 사용자의 편의를 돕기 위한 보너스입니다.
        '새로운 항목이 하나씩 추출될 때마다 상태표시줄에 현재까지 몇 개의 아이템이 출력되었는지를 알려
        '주고, 또 추출 아이템이 15개 이상일 경우 화면을 스크롤 시켜줌으로써 사용자가 조금이라도 덜 지루
        '해 하도록 하기 위한 작은 배려인 셈이지요.

et:
    Next intNum
    Application.StatusBar = ""
    MsgBox "총 " & intNum2 & "개의 Item을 추출하였습니다", , "//Exceller"
    '작업이 모두 끝났으면 총 몇 개의 아이템이 추출되었는지를 메시지 박스를 통해 다시 한번 사용자에게
    '알려주고 프로그램을 종료합니다.
End Sub

마무리

별로 어려운 부분이 없을 것입니다. 그런데 한 가지 문제가 있습니다. 뭐냐하면 검색할 자료가 얼마 없을 때에는 괜찮은데 검색해야 할 대상이 몇 천건 정도 된다면 이 프로그램을 실행할 때 시간이 엄청나게 많이 소요가 될 것입니다. 레코드가 많으면 많을수록 더욱 그러하지요. 그렇다면 어떻게 해야 할까요?

그 해결책에 대해서는 다음 시간에 설명을 드리겠습니다.

또한 응용력을 조금 발휘를 해서 UserForm 상에서 리스트 박스를 띄울 때 중복 아이템들을 제거하고 나 타나도록 하는 방법에 대해서도 알아보도록 하지요.

오늘은 여기까지…

정리 — 고유 값 추출 핵심

자주 묻는 질문 (FAQ)

마치며

엑셀 본연의 기능이 있는지 먼저 살펴본 다음, 필요할 때 코딩하는 습관을 들이시기 바랍니다.