Cell Merge

Step 1: 결과 미리 보기

보통 Excel에서 여러 개의 셀을 선택한 다음 "셀 병합"을 하게 되면 맨처음의 셀에 있는 내용만 표시가 되고 나머지는 모두 지워집니다.

즉, 위 세 개의 셀을 범위로 지정한 다음 "셀 병합" 버튼을 눌러 보세요. 그러면 "… 한 셀로 병합하며 맨 행의 왼쪽에 있는 데이터만 남게 됩니다."라는 메시지가 나타나고 "확인"을 클릭하면 세 개의 셀이 합쳐지긴 하는 데 Excel이라는 문자열만 남게 될 것입니다. 그런데 경우에 따라서는 여러 개의 셀을 병합하면서 그 내 용들을 모두 나타내고 싶은 경우가 있을 수 있겠지요?

아래의 세 셀을 선택한 후 버튼을 눌러 보세요.

어떻습니까? 원하는대로 작업이 잘 되지요? 이번 시간에는 이렇게 셀을 병합할 때 내용들도 함께 합쳤다가 다시 원상태로 되돌리는 방법(셀머지라고 이름을 지어 보았습니다)에 대해 알아보도록 하겠습니다. 코드를 살펴 볼까요?

Step 2: 코드 살펴보기

Sub CellMerge()
    Dim strTemp As String
    Dim intCount As Integer
    Dim intNum As Integer
    Dim strCell() As String
    Dim strYesNo As String
    '언제나 그렇듯이 배역을 먼저 정합니다. 변수 중에서 strCell()이라는 배열변수가 있습니다.
    '이것은 사용자가 실수로 셀 병합을 했을 경우 이것을 원래대로 되돌리기 위해 각 셀의 내용들을
    '담아두는 변수입니다. 특히 변수 선언시 배열의 크기를 지정하지 않는 변수를 '동적 배열변수'라고
    '합니다.

    Application.DisplayAlerts = False
    '특정 작업을 할 때(예를 들어 워크시트를 지울 때) 보면  "…작업을 계속 할까요 말까요?…"하고 물어
    '오지요? 그런데 DisplayAlerts 속성을 False로 지정해 두면 묻지 않고 바로 실행을 하게 됩니다.

    intNum = Selection.Cells.Count
    ReDim strCell(1 To intNum) As String
    '선택된 영역의 셀 수를 세어서 intNum 이라는 변수에 담아 둡니다.
    '그런 다음 ReDim(ReDimension) 즉, 변수 재선언문에 의해 선택된 셀 수만큼 변수를 만듭니다.
    '그래야 나중에 사용자가 작업 취소를 할 경우, 각 셀에 원래내용을 다시 뿌려줄 수가 있는 것이지요.

    With Selection
        If .Areas.Count <> 1 Then
            Application.DisplayAlerts = True
            MsgBox "셀 범위를 다시 선택하세요!", , "//Exceller"
            Exit Sub
        End If
        '이 부분은 에러를 체크하기 위한 에러 검문소입니다.
        '즉 셀병합을 하려면 연속된 영역이어야 하는데 사용자가 Ctrl키 등을 눌러 불연속적인 셀들을 선택하고
        '이 프로시저를 실행하려 할 경우, 에러 메시지를 나타내 주고 프로시저를 강제로 종료시킵니다.
    End With

    For intCount = 1 To intNum
        strTemp = strTemp & Selection.Cells(intCount)
        strCell(intCount) = Selection.Cells(intCount)
        'intNum 변수에는 지정된 영역의 셀 수값이 들어 있지요? 그러므로 For~Next 순환문에 의해 해당
        '횟수만큼 순환을 하면서 각 셀의 문자들을 &연산자를 써서 모두 연결을 하여 strTemp라는 변수에
        '저장을 해 둡니다.
        '그리고 나중에 셀 병합한 것을 원상태로 되돌리기 위해 각 셀의 내용을 동적 배열변수 strCell()에다
        '차곡차곡 담아두지요.
    Next intCount

    Selection.Merge
    Selection = strTemp
    '선택된 영역을 하나로 합친 다음(Merge), strTemp 변수에 저장된 내용을 뿌려줍니다.
    '이렇게 하면 셀 병합을 하면서 동시에 각 셀의 내용들도 연결이 되는 것이지요.
    '아래 부분은 만약에 사용자가 실수로 셀 병합을 했을 경우 이것을 원래대로 되돌리기 위한 과정입니다.

    strYesNo = MsgBox("자료가 합쳐졌지요?" & vbCr _
        & "셀을 원래대로 돌릴까요?", vbYesNo, "//Exceller")

    Application.DisplayAlerts = True
    If strYesNo = vbNo Then Exit Sub
    Selection.UnMerge
    'Merge는 선택된 영역을 하나로 합치는 기능이고 UnMerge는 그 반대이지요.
    For intCount = 1 To intNum
        Selection.Cells(intCount) = strCell(intCount)
        '지정된 영역의 셀 수만큼 반복을 하면서 동적 배열변수에 들어있던 내용을 각 셀로 다시 돌려줍니다.
    Next intCount
End Sub

마무리

생각하신 것보다 쉽지요? 그 반대입니까? 설령 코드는 눈에 잘 들어오지 않는다 하더라도 어떤 과정을 통해 이 작업이 가능하게 되는지는 잘 생각해 두시는 것이 좋습니다. Flow를 잘 한번 그려 보세요.

프로그래밍 기교, 코드 몇 줄 짜는 것도 중요하지만 그보다 더 중요한 것은 논리적인 사고를 길러나가는 것 이겠지요.

다음에 또…

정리 — 셀 병합 핵심

자주 묻는 질문 (FAQ)

마치며

코드 몇 줄보다 중요한 것은 논리적인 사고를 기르는 것입니다. Flow를 직접 그려 보시기 바랍니다.