화면크기 조절하기 & 시트 스크롤링

Step 1: 유저폼 만들기

(1) VB Editor 상태에서(Alt + <F11>), 빈 유저폼(UserForm)을 하나 삽입합니다.

(2) 아래의 그림을 참고하여 컨트롤들을 삽입한 다음, 속성을 변경해 줍니다.

아이엑셀러

① Frame 컨트롤

② Label 컨트롤

③ ScrollBar 컨트롤

④ CommandButton 컨트롤

Step 2: 코드 작성하기

(3) 이제 각 컨트롤에 지능을 부여하는 작업입니다.

(1) 모듈 맨 위의 상수 선언

먼저, 코드 창의 맨 위 부분에 아래의 한 줄을 첨가합니다.

Option Explicit
Const strZoom = "현재 화면 배율은 "
'//이처럼 모듈시트의 맨 앞부분에 즉, 프로시저가 시작되기 전에 변수(또는 상수)를 지정해 주면
'//그 모듈시트 내의 어느 프로시저에서든 Dim으로 별도 선언하지 않고서도 사용을 할 수가 있는
'//것입니다. 그런데 새로운 것이 하나 나왔지요? 지금까지는 변수를 선언할 때는 Dim으로 선언을
'//해 주었는데 이번에는 Const로 선언을 했군요. 변수란 Variable 즉, 변할 수 있는 값을 말합니다.
'//그런데 변화하지 않는 값에 대해서는 이렇게 Const(Constants, 상수)로 선언을 합니다. 변수가
'//아닌 상수를 선언해 주는 것입니다.

(2) 초기화 이벤트

다음으로, 유저폼 내에서 컨트롤이 없는 빈 영역을 더블클릭해서 코드 창을 불러 냅니다. 현재 상태에서는 Private Sub UserForm_Click()이라는 이벤트가 발생하게 될 것입니다. 이벤트 선택 버튼에서 Initialize를 선택하면 Private Sub UserForm_Initialize 이벤트가 나타나는데 이 이벤트는 아래의 코드를 입력합니다.

Private Sub UserForm_Initialize()
    lblZoom.Caption = strZoom & ActiveWindow.Zoom & "% 입니다"
    '//ActiveWindow, 즉 활성화 된 윈도우의 배율을 lblZoom이라는 Label 컨트롤의 캡션값에 집어
    '//넣습니다.

    With scrZoom
        .Min = 50
        .Max = 300
        .SmallChange = 1
        .LargeChange = 10
        .Value = ActiveWindow.Zoom
        '//scrZoom이라는 스크롤바 컨트롤의 최소값을 50, 최대값을 300으로 지정합니다.
        '//그런 다음, SmallChange라는 것은 스크롤바의 좌/우 버튼을 한번 클릭할 때마다 변화하는
        '//값을 지정하는 속성인데 이 값을 1로 지정해 줍니다.
        '//LargeChange 속성은 스크롤바의 버튼 이외의 부분을 클릭할 때 변화하는 값을 지정하는
        '속성으로 이 값은 10으로 지정을 해 줍니다.
    End With

    With scrColumns
    '//시트 스크롤링과 관련된 컨트롤 중에서 가로 방향 스크롤과 관련된 컨트롤의 속성을 변경하는
    '//부분입니다.
        .Min = 1
        .Max = Application.WorksheetFunction.Min(ActiveSheet.Columns.Count, 32767)
        '//최대값은 현재 시트의 컬럼수와 같겠지요?
        .SmallChange = 1
        .LargeChange = 10
        .Value = ActiveWindow.ScrollColumn
        '//ScrollColumn 속성은 맨 좌측열의 열번호를 리턴해 줍니다. 따라서 현재 윈도우의 맨 좌측
        '//열 값을 Value 속성에 담아둡니다.
    End With

    With scrRows
        .Min = 1
        .Max = Application.WorksheetFunction.Min(ActiveSheet.Rows.Count, 32767)
        .SmallChange = 1
        .LargeChange = 10
        .Value = ActiveWindow.ScrollRow
        '//ScrollRow 속성은 최상단 행값을 리턴합니다. 그러므로 현재 윈도우의 최상단 행값을
        '//Value 속성에 저장을 해 둡니다.
    End With
End Sub

(3) 화면 배율 스크롤바

(4) Shift + <F7> 키를 눌러 유저폼을 다시 불러 낸 다음, scrZoom 컨트롤을 더블클릭 하면 scrZoom_Click 이벤트가 나타나는데 아래의 코드를 입력합니다.

Private Sub scrZoom_Change()
    With ActiveWindow
        .Zoom = scrZoom.Value
        lblZoom.Caption = strZoom & .Zoom & "% 입니다"
        '//scrZoom이라는 스크롤바의 Value 속성값을 현재 윈도우의 Zoom 값으로 대치하였군요.
        '//그런 다음, 현재 윈도우의 줌값에 "% 입니다"라는 문자열을 더하여 lblZoom이라는 레이블
        '//컨트롤의 캡션값을 이것으로 대치합니다.
    End With
End Sub

(4) 가로 스크롤바

(5) Shift + <F7> 키를 다시 눌러 유저폼을 호출한 다음, scrColumns 컨트롤을 더블클릭 하면 아래와 같은 Change 이벤트가 나타날 것입니다. 이 이벤트에 다음의 한 라인을 추가합니다.

Private Sub scrColumns_Change()
    ActiveWindow.ScrollColumn = scrColumns.Value
    '//scrColumns라는 스크롤바 컨트롤의 Value 값만큼 화면을 좌/우로 스크롤링 하게 되겠지요?
End Sub

(5) 세로 스크롤바

(6) Shift + <F7>을 누르고 이번에는 scrRows 컨트롤을 더블클릭한 다음 아래의 코드를 추가합니다.

Private Sub scrRows_Change()
    ActiveWindow.ScrollRow = scrRows.Value
    '//(5)와 거의 비슷한데 단지 방향만 틀릴 뿐이지요.
End Sub

(6) Close 버튼

(7) 다시 Shift + <F7>키를 누르고 이번에는 Close 버튼을 더블클릭 한 다음 코드를 삽입합니다.

Private Sub btnClose_Click()
    Unload Me
End Sub

(7) 유저폼 호출

(8) 마지막으로, 이 유저폼을 호출할 프로시저를 일반 VBA 모듈에 만듭니다.

Sub ShowForm()
    UserForm1.Show
End Sub

이제 워크시트 상에서 위 프로시저를 지정해 주면 실행이 될 것입니다. 이상 끄~읕!

마무리

다음 시간에…

정리 — 화면 제어 핵심

자주 묻는 질문 (FAQ)

마치며

기초만 잘 익혀 두면 그 다음은 응용의 문제입니다.