처음 만들어보는 UserFormⅡ

Step 3: 이벤트 핸들러 프로시저 작성하기

지난 시간에 유저폼을 작성한 다음 이것을 화면에 나타내는 작업까지 했었습니다. 이번 강좌에서는 이 유저폼에 지능을 부여하는 작업, 즉 이벤트 핸들러 프로시저를 작성하여 컨트롤에 붙이는 방법에 대해 설명을 드리겠습니다.

(1) VB Editor 실행하기

"도구-매크로-Visual Basic Editor" 메뉴 또는 Alt + F11 키를 눌러 VB Editor를 실행시킵니다.

(2) Cancel 버튼 더블클릭하기

(2) 지난 시간에 만들었던 유저폼이 화면상에 나타났는지 확인한 다음(나타나 있으면) Cancel 버튼을 더블클릭 합니다(유저폼이 아닌 다른 것이 나타나 있다면 "프로젝트 탐색기 창"에서 유저폼을 더블 클릭하시면 됩니다).

(3) 이벤트 핸들러 프로시저 확인하기

(3) 그러면 새로운 모듈 시트(이것을 코드 시트라고 부릅니다)가 하나 나타나면서 btnCancel_Click이라는 (빈) 프로시저가 하나 나타날 것입니다.

Private Sub btnCancel_Click()

End Sub

여기서 "이벤트"라는 아주 중요한 개념이 하나 나왔습니다. 우리말로 직역을 하면, "사건, 행사"가 되나요? ^^ 이벤트라고 하니까 뭔가 거창한 것처럼 여겨지는데... 우리가 워크시트(또는 유저폼) 상에서 어떤 키를 눌렀다든가 마우스를 클릭했다든가 하는 하나하나의 동작이 바로 이벤트라고 생각하시면 되겠습니다. 유저폼 내의 컨트롤(유저폼 그 자체도 마찬가지!)은 사용자나 Excel에 의해 특정한 이벤트가 발생 됩니다. 예를 들어 버튼을 클릭하면 CommandButton_Click 이벤트가 발생 됩니다. 그리고 어떤 동작은 복수 개의 이벤트(Multiple Event)를 발생시킵니다. 예를 들어, 위쪽 화살표를 클릭하는 동작은 (1) SpinUp 이벤트와 (2) Change 이벤트를 동시에(엄밀하게 말하면 순차적으로) 발생시킵니다.

또 한가지 예로, 유저폼이 Show 메서드에 의해 로딩이 되면(Excel에 의해 자동으로) Initialize 이벤트와 Activate 이벤트가 발생이 됩니다(좀 복잡하지요?).

따라서 위의 경우, btnCancel_Click 이라는 것은 btnCancel이라는 버튼을 클릭했을 때 자동으로 생기는 클릭이벤트라고 할 수가 있는 것이지요. 그렇다면 btnCancel이라는 해괴한(?) 문자는 어디서 나온 것이냐?'고 반문하는 분이 계신가요?

지난 시간에 유저폼에 여러 가지 종류의 컨트롤을 추가하고 속성값을 변경해 줄 때 취소(Cancel) 버튼의 Name 속성을 btnCancel로 바꾸어 주었지요? 그래서 이 버튼을 클릭하니까 자동적으로 btnCancel_Click이라는 클릭 이벤트가 하나 자동으로 생겨난 것입니다. 이해가 되십니까?

이제 이 클릭 이벤트에 이런 코드를 입력합니다.

Private Sub btnCancel_Click()
    Unload UserForm1
End Sub

이것은 [취소] 버튼을 클릭했을 때, 유저폼을 닫는 것입니다.

(4) 유저폼으로 돌아가기

(4) 위와 같이 코드 입력 작업이 완료되었으면 Shift + F7키를 누릅니다. 그러면 좀전의 유저폼이 다시 나타날 것입니다.

(5) OK 버튼 코드 입력하기

(5) 이번에는 OK 버튼을 더블 클릭합니다. 이번에는 btnOK_Click 이라는 (빈) 이벤트 핸들러 프로시저가 나타나는데 여기에는 아래의 코드를 그대로 입력합니다(코드가 너무 복잡하도고 생각하시는 분은 복사를 하셔도 됩니다).

Private Sub btnOK_Click()
    Dim intRow As Long
    '//입력된 행 수를 카운트 할 변수 지정합니다.

    Sheets("Sheet2").Select
    intRow = Application.CountA(Range("a:a")) + 1
    '//이름이 입력된 A열 중에서 값이 공란인 것이 몇번째 열인지를 찾아서 그 값에 +1을 한 다음,
    '//intRow 변수에 대입합니다.
    Cells(intRow, 1) = txtName.Text
    '//A열의 빈란으로 가서 txtName 컨트롤의 Text 즉 텍스트 상자의 값을 대입시킵니다.

    If optMale Then
        Cells(intRow, 2) = "남성"
    ElseIf optFemale Then
        Cells(intRow, 2) = "여성"
    Else
        Cells(intRow, 2) = "미상"
    End If
    '//optMale이 체크되었으면 "남성"을, optFemale 버튼이 체크되었으면 "여성"을,
    '//이것도 저것도 아니면 "미상"이라는 문자열을 공란이 발견된 행에서 오른쪽으로 한 간
    '//옆으로 이동해서 대입합니다.

    txtName.Text = ""
    optUnknown = True
    txtName.SetFocus
    '//해당 셀에 대입하는 작업이 끝났으면 txtName 컨트롤의 값을 공란으로,
    '//optUnknown 컨트롤에는 체크를, 그리고 txtName 컨트롤로 포인터를 옮겨놓은 후
    '//프로시저를 종료합니다.
End Sub

마무리

이렇게 해서 간단한 유저폼을 하나 만들어 보았는데 어떠신지… 아마 '생각보다 간단하군!' 하고 생각하시는 분도 있을 것이고, 또 어떤 분은 '이거 뭐가뭔지 하나도 모르겠다!' 하고 생각하시는 분도 있을 것입니다.

"Excel에 날개달기" VB(A) 강좌, 특히 코드 부분은 제가 머리카락을 뜯어가며 어떻게 하면 좀더 쉽게 자알 설명했다고 소문이 날까?' 생각에 생각을 거듭하여 생각해 낸 산물입니다.

그냥 소설책 읽듯이 그냥 눈으로만 한번 보고 휙~~ 버리지 마시기 바랍니다. 한번 봐서 이해가 안 가시면 시간이 좀 지난 다음에 두번, 세번 계속 들여다 보세요. 그러면 어느 순간에 가서는 이해가 되실 것입니다. 어렵기 때문에 도전해서 성취할 가치가 있는 것이지요.

다음 시간에…

정리 — 이벤트 핸들러 핵심 정리

자주 묻는 질문 (FAQ)

마치며

한 번 봐서 이해가 안 가시면 시간이 지난 뒤 두 번, 세 번 계속 들여다 보세요. 어렵기 때문에 도전해서 성취할 가치가 있습니다.