실행순서제어하기Ⅱ

Step 1: For ~ Next 문

Loop block을 만드는 가장 간단한 방법이 For ~ Next 구문입니다. 몇 강좌 전에 설명을 드렸던 For Each ~ Next 문이 바로 For ~ Next의 한 형태입니다.

For counter = 시작 To 끝 [Step 값]
    … 어쩌고 …
    … 저쩌고 …
Next [counter]

위에 예시한 것이 For ~ Next 문의 가장 일반적인 형태라고 할 수 있습니다.

Sub ForNextDemo()
    Dim intSum As Double     '제곱근의 합을 저장할 변수 선언
    Dim intCount As Integer  '반복회수를 지정할 변수 선언

    For intCount = 1 To 100
        intSum = intSum + Sqr(intCount)
    Next intCount

    MsgBox "1부터 100까지의 제곱근의 합계는 " & intSum & " 입니다.", , "//Exceller"
End Sub

먼저 변수를 선언해 주었지요. 항상 변수를 선언하고 쓰는 버릇을 들이도록 하세요.

For ~ Next 구문이 나왔네요. intCount가 1부터 100까지 즉 1, 2, 3,… 100까지 돌면서 각 숫자의 제곱근 값을 intSum이라는 실수형(Double) 변수에 차곡차곡 담아두지요. For intCount = 1 To 100 다음에 Step 부분을 생략하면 디폴트값으로 1이 지정이 됩니다. 만약 홀수에 해당되는 숫자들의 제곱근의 합을 구하려면 For intCount = 1 To 100 Step 2라고 해주면 되겠지요?

순환이 모두 끝났으면 100번을 순환하면서 intSum 변수에 그동안 담아둔 제곱근 값의 합계를 화면에 뿌려줍니다.

조금 응용을 해 볼까요? 즉 위의 경우에는 시작되는 값과 끝나는 값이 고정이 되어 있었는데(1~100) 시작값과 끝나는 값을 사용자가 마음대로 변경을 할 수 있도록 해보는 것입니다. 아래의 버튼을 눌러 보세요.

Sub ForNextDemo2()
    Dim lngStart As Long
    Dim lngEnd As Long
    Dim dblSum As Double
    Dim lngCount As Long

    lngStart = InputBox("시작할 숫자는?", "//Exceller")
    lngEnd = InputBox("끝나는 숫자는?", "//Exceller")
    If lngStart >= lngEnd Then
        MsgBox "시작할 숫자가 끝나는 숫자보다 크면 안됩니다!!!", , "//Exceller"
        Exit Sub
    End If

    For lngCount = lngStart To lngEnd
        dblSum = dblSum + Sqr(lngCount)
    Next lngCount
    MsgBox lngStart & " 에서 " & lngEnd & " 까지의 제곱근의 합계는 " & _
        dblSum & " 입니다.", , "//Exceller"
End Sub

사용자가 마음대로 값을 변경해 가며 테스트를 해볼 수가 있겠지요? 응용력을 발휘하면 아주 재미있는 것을 만들수 있을 것 같지 않습니까? 한번 연습해 보시기 바랍니다.

Step 2: Do ~ While 문

Loop block을 만드는 또한가지 방법은 Do ~ While 문을 사용하는 것입니다. 이것은 특정한 조건을 만족하는 동안에는 계속해서 특정 명령을 수행하는 것으로 Do ~ While문은 아래의 두가지 형태를 가집니다.

Do [While 조건]
    … 어쩌고 …
    … 저쩌고 …
    Exit Do
    … 어쩌고 저쩌고 …
Loop

Do
    … 어쩌고 …
    … 저쩌고 …
    Exit Do
    … 어쩌고 저쩌고 …
Loop [While 조건]

이 두가지 형태의 차이점은 다음의 예제를 보시면 명확해 집니다.

Sub DoWhileDemo()
    Do While Not IsEmpty(ActiveCell)
        ActiveCell.Value = 0
        ActiveCell.Offset(1, 0).Select
    Loop
End Sub

이 프로시저는 현재 셀포인터가 위치해 있는 셀을 시작으로 해서 아래로 한간씩 내려가면서 0(zero)을 셀에 삽입합니다. 그리고 루프문을 한바퀴씩 돌 때 마다 그 다음의 셀을 ActiveCell로 설정을 해 주고 있습니다. 따라서 경우에 따라서 이 프로시저는 Do ~ Loop 내의 실행문을 한번도 실행하지 않을 수도 있겠지요? 즉, 맨 처음 셀부터 아무 값도 입력된 것이 없다면 아예 한번도 실행되지가 않을수 있습니다.

왜냐구요? Do문 안으로 들어가기 전에 조건 비교를 미리 해서 ActiveCell이 공란이면 Do ~ Loop 안으로 들여보내지를 않기 때문이지요.

그런데 아래의 경우에는 어떤가요?

Sub DoWhileDemo2()
    Do
        ActiveCell.Value = 0
        ActiveCell.Offset(1, 0).Select
    Loop While Not IsEmpty(ActiveCell)
End Sub

이번에는 While이 Loop 다음에 있습니다. 이 때에는 Do ~ Loop 사이에 있는 실행문을 적어도 한번은 실행을 하게 되지요.

결국, 이 두가지 형식의 차이점은 어느 시점에서 Loop문을 종료하느냐의 차이인 것입니다. 그렇지만 실제 결과를 놓고보면 같게 되지요.(적어도 위의 경우에는…)

Step 3: Do ~ Until 문

Do ~ Until 루프문은 Do ~ While 문과 흡사합니다. 차이점은 Do While 문은 조건식이 True인 동안에는 명령을 계속 수행하는데 비해, Do Until 문은 조건식이 True가 될 때까지 명령을 수행합니다.

Do [Until 조건]
    … 어쩌고 …
    … 저쩌고 …
    Exit Do
    … 어쩌고 저쩌고 …
Loop

Do
    … 어쩌고 …
    … 저쩌고 …
    Exit Do
    … 어쩌고 저쩌고 …
Loop [Until 조건]

While이 Until로 바뀌었다는 것 말고는 Do ~ While 구문과 똑같은 형태지요? 사용예제 역시 마찬가지입니다. While을 Until로 바꿔줄려면 True와 False를 서로 바꿔주면 되겠지요? 즉 아래와 같이 말입니다.

Sub DoUntilDemo()
    Do Until IsEmpty(ActiveCell)
        ActiveCell.Value = 0
        ActiveCell.Offset(1, 0).Select
    Loop
End Sub

Sub DoUntilDemo2()
    Do
        ActiveCell.Value = 0
        ActiveCell.Offset(1, 0).Select
    Loop Until IsEmpty(ActiveCell)
End Sub

이렇게 말입니다. 실행순서를 제어하는 구문은 실제 프로그래밍 작업시 빈번하게 사용되는 것들입니다. 다섯 가지 밖에 안되므로 잘 정리해 두시기 바랍니다.

마무리

다음 시간에 또…

정리 — 반복문 핵심 정리

자주 묻는 질문 (FAQ)

마치며

실행순서를 제어하는 구문은 실제 프로그래밍에서 빈번하게 사용되는 것들이며 다섯 가지뿐이므로 잘 정리해 두시기 바랍니다.