매크로 기록 기능에 대하여

Step 1: 매크로 기록 따라해 보기

백문이 불여일견, 백견이 불여일타지요? 직접 해 보도록 하지요.

1. 새로운 워크북(파일)을 하나 만듭니다.
2. 만약 창크기가 최대로 되어 있다면 크기를 줄여 적당한 크기로 만듭니다.
3. VB Editor를 활성화 시킵니다.(Alt + F11키를 누르거나 "도구-매크로-Visual Basic Editor"를 선택하면 되겠지요?)
4. 그런 다음에 엑셀창과 VBE 창의 크기를 아래와 같이 적당히 조절하여 두 창의 내용이 모두 잘 보이도록 설정해 줍니다.

아이엑셀러

5. 엑셀창을 활성화시키고(요 부분을 마우스로 클릭해 주면 되겠지요?), "도구-매크로-새 매크로 기록" 메뉴를 선택합니다.
6. VB Editor를 활성화시키고 Module1을 더블클릭 합니다. 그러면 모듈시트의 내용이 화면에 나타납니다. 물론 아직 기록된 게 없으므로 그냥 흰 화면만 나타나지요.
7. 다시 엑셀창을 활성화시키고 기록을 시작합니다. 지금부터 기록하는 것은 이 부분에 하나씩 하나씩 기록이 되어질 것입니다(당연히 자동으로 기록이 됩니다).
8. a1셀에 "1월"이라고 입력을 합니다(인용부호는 빼고!). 나머지 셀에 대해서도 아래의 그림과 같이 입력을 합니다.

아이엑셀러

9. 입력이 끝났으면 기록중지 버튼을 누르거나 "도구-매크로-기록 중지" 메뉴를 선택합니다.

Step 2: 기록된 코드 살펴보기

제대로 기록이 되었다면 아마 아래와 같은 형태의 코드가 기록이 되어져 있을 것입니다.

Sub Macro1()
'
' Macro1 Macro
' 권현욱이(가) 2000-04-30에 기록한 매크로
'
    Range("A1").Select
    ActiveCell.FormulaR1C1 = "1월"
    Range("B1").Select
    ActiveCell.FormulaR1C1 = "2월"
    Range("C1").Select
    ActiveCell.FormulaR1C1 = "3월"
    Range("A2").Select
    ActiveCell.FormulaR1C1 = 1000
    Range("B2").Select
    ActiveCell.FormulaR1C1 = 900
    Range("C2").Select
    ActiveCell.FormulaR1C1 = 1500
    Range("C3").Select
End Sub

생각보다 복잡하지요? 사실 이 코드는 불필요한 요소들이 많이 포함되어 있습니다. 그다지 효율적인 코드라고는 할 수가 없는 것이지요. 이것과 똑같은 기능을 수행하지만 보다 간단한 형태로 직접 입력을 해 보지요.

Sub Modified1()
    Range("a1").Select
    ActiveCell.Offset(0, 0) = "1월"
    ActiveCell.Offset(0, 1) = "2월"
    ActiveCell.Offset(0, 2) = "3월"
    ActiveCell.Offset(1, 0) = 1000
    ActiveCell.Offset(1, 1) = 900
    ActiveCell.Offset(1, 2) = 1500
End Sub

ActiveCell이라는 것은 현재 셀포인터가 위치해 있는 셀을 가리키는 것입니다. 그리고 Offset() 함수는 "이런 기능 아세요?" 시간에 몇번 설명을 드렸던 기억이 나는데 이해하시는지? ActiveCell.Offset(1,2)라고 하게 되면 현재 셀에서 밑으로 한칸, 오른쪽으로 2칸 옮겨가라"는 명령입니다.

만약 현재셀(즉 ActiveCell)이 A1이라면, ActiveCell.Offset(1,2)라고 하게 되면 결과는 C2, 즉 셀 포인터는 C2 셀로 이동이 되어 있겠지요?

여기서 또 한가지 주의해야 할 점! 보통 수학에서 A=B라고 하게 되면 "A와 B는 같다"라는 것을 의미하지요? 그런데 프로그래밍 언어에서는 그렇지 않습니다. 이것을 어떻게 받아들이느냐 하면 "오른쪽에 있는 (변수)값을 왼쪽에 대입(assign)하라"로 인식을 하게 되지요. 물론 예외는 있습니다. If 구문에서 조건식 부분에 쓰게 되면 서로 같은지를 비교하는 형태가 되긴 하지만 그것은 말그대로 예외적인 경우이고 그 이외의 경우에는 우변의 값을 좌변의 변수에 대입하라는 의미입니다.

그런데 위와 같이 코딩을 하는 사람은 아마 아무도 없을 것입니다. 우리는 지금 배우는 단계니까 이렇게 하지만... 이렇게 짜서는 어디가서 프로그램 짠다고 명함도 못내밀 것입니다. ^^ 왜냐하면 위의 동그라미 친 부분, 즉 ActiveCell이라는 문장이 계속 반복이 되어 나타나지요? 이렇게 되면 모양도 모양이지만 수행속도도 느려터지게 됩니다. 조직에서도 반복되는 요소가 많으면 비효율적인 것이 되듯이 프로그래밍에서도 이것은 마찬가지이지요.

Step 3: With ~ End With로 단축하기

위의 코드는 With ~ End With 구문을 사용하여 아래와 같이 또 단축시킬 수가 있습니다.

Sub Modified2()
    Range("a1").Select
    With ActiveCell
        .Offset(0, 0) = "1월"
        .Offset(0, 1) = "2월"
        .Offset(0, 2) = "3월"
        .Offset(1, 0) = 1000
        .Offset(1, 1) = 900
        .Offset(1, 2) = 1500
    End With
End Sub

훨씬 읽기도 용이하지요? 실제 프로그래밍을 할 때는 대개 위 Modified2와 같은 형태로 코딩을 합니다.

Sub Modified3()
    Range("A1:C1").Value = Array("1월", "2월", "3월")
    Range("A2:C2").Value = Array(1000, 900, 1500)
End Sub

정리

오늘의 내용을 요약하자면, 매크로 기록에 의해 작성된 코드는 항상 효율적인 것은 아니라는 것! 따라서 기본적인 형태만 참고한 후 가독성과 수행속도를 높일 수 있도록 코드를 최적화(전문용어로 Optimizing 이라고 합니다) 시켜야 한다는 것! 이것을 명심하도록 하세요.

또 한가지 중요한 Offset() 함수와 With ~ End With 구문의 사용법을 명확히 이해하고 넘어 가시도록!(Offset() 함수는 X0024 강좌에 상세히 설명되어 있습니다)

마무리

오늘은 여기까지…

정리 — 매크로 기록 최적화 요약

자주 묻는 질문 (FAQ)

마치며

매크로 기록으로 만든 코드는 기본적인 형태만 참고하고, 가독성과 수행속도를 높이도록 최적화하는 것을 명심하시기 바랍니다.