[E3] =SUMPRODUCT((LEFT($B$3:$B$18,2)=D3)*1)

데이터 형식을 맞추는 방법 정리

방법 1: VALUE 함수를 이용하여 문자를 숫자로 변경

VALUE 함수를 이용하면 문자열 형태의 숫자값을 온전한 숫자로 변환할 수 있습니다.

[E3] =SUMPRODUCT((VALUE(LEFT($B$3:$B$18,2))=D3)*1)

방법 2: '--'를 이용하여 문자를 숫자로 변경

VALUE 함수 대신 더블 마이너스, 즉 마이너스(-)를 두 번 연속해서 문자열 형태의 숫자 앞에 붙여줍니다.

[F3] =SUMPRODUCT((--(LEFT($B$3:$B$18,2))=$D3)*1)

방법 3: 숫자 '1'을 곱하여 문자를 숫자로 변경

문자열 형태의 숫자에 1을 곱하면 온전한 숫자로 바꿀 수 있습니다.

[G3] =SUMPRODUCT(((LEFT($B$3:$B$18,2)*1)=$D3)*1)

이상 세 가지는 문자 형태의 숫자 데이터를 숫자로 바꾸는 방법이었습니다. 숫자를 문자열로 변환해도 같은 결과를 얻을 수 있습니다.

방법 4: 숫자 뒤에 공백 문자열을 추가하여 문자열로 변환

& 연산자를 이용하여 숫자 뒤에 빈 문자열을 연결하면 문자열 데이터가 됩니다. 그 결과값을 LEFT 함수로 추출한 결과값과 비교해 주는 원리입니다.

[H3] =SUMPRODUCT((LEFT($B$3:$B$18,2)=$D3&"")*1)

방법 5: TEXT 함수를 이용하여 문자열로 변환

& 연산자 대신 TEXT 함수를 이용하여 숫자를 문자열로 변환할 수 있습니다.

[I3] =SUMPRODUCT((LEFT($B$3:$B$18,2)=TEXT($D3,"@"))*1)

방법 6: 배열 수식(Array Formula) 사용

배열 수식을 사용할 수도 있습니다.

[J3] {=SUM(IF(VALUE(LEFT($B$3:$B$18,2))=$D3,1,0))}

이 정도면 어느 정도 정리가 된 것 같습니다. 가장 편한 방법을 사용하시면 되겠습니다. 다른 좋은 방법을 알고 있는 분은 알려주시고요.

정리 — 데이터 형식 맞추는 6가지 방법

방법	방향	핵심 수식
1. VALUE 함수	문자→숫자	VALUE(LEFT(...))
2. 더블 마이너스	문자→숫자	--(LEFT(...))
3. 1 곱하기	문자→숫자	LEFT(...)*1
4. 빈 문자열 연결	숫자→문자	$D3&""
5. TEXT 함수	숫자→문자	TEXT($D3,"@")
6. 배열 수식	문자→숫자	{SUM(IF(VALUE(...)=D3,1,0))}

자주 묻는 질문 (FAQ)

마치며

VBA에 대한 기초 지식을 공부하실 분은 아이엑셀러 닷컴 사이트 상단 메뉴에서 [Excel 강의] - [Excel 입문]을 먼저 보시면 이해하기 쉽습니다.