주민/외국인 등록번호로 성별 알아내는 방법 총정리

방법 1: IF + 텍스트 함수 사용

먼저, 가장 만만한(?) IF 함수를 써서 해결해 보죠. MID 함수를 이용하여 번호 뒷자리 첫 번째 수를 구한 다음 중첩 IF 문을 작성합니다. VALUE는 숫자 형식의 문자열 데이터를 온전한 숫자로 바꿔주는 함수입니다.

C3:
=IF(VALUE(MID(B3,8,1))=1,"남", IF(VALUE(MID(B3,8,1))=2,"여",
IF(VALUE(MID(B3,8,1))=3,"남", IF(VALUE(MID(B3,8,1))=4,"여",
IF(VALUE(MID(B3,8,1))=5,"남",IF(VALUE(MID(B3,8,1))=6,"여",
IF(VALUE(MID(B3,8,1))=7,"남","여")))))))

수식이 마냥 길어지는 게 부담스럽다면 적당한 셀(E3)에 뒷자리 첫 번째 수를 구하고 수식에 적용하면 길이가 대폭 줄어듭니다.

=IF(E3=1,"남",IF(E3=2,"여",IF(E3=3,"남",IF(E3=4,"여",
IF(E3=5,"남",IF(E3=6,"여",IF(E3=7,"남","여")))))))

지금부터는 E3 셀에 뒷자리 첫 번째 수가 구해져있다고 가정하고 진행하겠습니다.

=VALUE(MID(B3,8,1))

방법 2: IFS 함수 사용 (엑셀 2019)

엑셀 2019버전을 사용한다면 IFS 함수를 사용해 보세요. IF를 반복해서 적지 않아도 되기 때문에 수식의 길이가 대폭 줄어듭니다.

C3:
=IFS(E3=1,"남",E3=2,"여",E3=3,"남",E3=4,"여",
E3=5,"남",E3=6,"여",E3=7,"남",TRUE,"여")

방법 3: CHOOSE 함수 사용

CHOOSE 함수를 이용하면 더욱 구조적이고 이해하기 쉬운 수식이 될 수 있습니다.

C3:
=CHOOSE(E3,"남","여","남","여","남","여","남","여")

방법 4: IF + 논리 함수 사용

논리 함수의 하나인 OR를 IF와 조합하여 해결할 수도 있습니다.

C3:
=IF(OR(E3=1,E3=3,E3=5,E3=7),"남","여")

방법 5: IF + 정보 함수 사용

정보 함수의 하나인 ISODD(홀수 여부 판단), ISEVEN(짝수 여부 판단) 함수를 이용하면 지정한 숫자가 홀수인지 짝수인지 여부를 알 수 있습니다. 이 특성을 이용하여 IF 함수와 조합해서 사용합니다.

C3:
=IF(ISODD(E3),"남","여") 또는
=IF(ISEVEN(E3),"여","남")

일단 이 정도 방법들이 떠오르는군요. 다른 방법도 있을 수 있으므로 연구해 보시기 바랍니다.

정리 — 다섯 가지 성별 판별 수식 비교

방법	함수	특징
1. IF 중첩	IF, MID, VALUE	가장 기본적, 수식이 길어짐
2. IFS	IFS (2019+)	중첩 없이 조건 나열
3. CHOOSE	CHOOSE	구조적이고 이해하기 쉬움
4. IF+OR	IF, OR	홀수 조건을 하나로 묶음
5. IF+ISODD/ISEVEN	IF, ISODD, ISEVEN	가장 짧고 직관적

자주 묻는 질문 (FAQ)

마치며

VBA에 대한 기초 지식을 공부하실 분은 아이엑셀러 닷컴 사이트 상단 메뉴에서 [Excel 강의] - [Excel 입문]을 먼저 보시면 이해하기 쉽습니다.