엑셀 여러 가지 기준으로 카운팅하기, COUNTIFS·SUMPRODUCT·배열 수식

1. 실적이 200 이상 300 미만인 경우

Excel 2007 이상:

=COUNTIFS(E24:E53,">=200",E24:E53,"<300")

Excel 2007 이전:

=COUNTIF(E24:E53,">=200")-COUNTIF(E24:E53,">=300")

배열 수식 사용:

{=SUM((E24:E53>=200)*(E24:E53<300))}

결과는 세 수식 모두 6입니다.

배열 수식의 경우, 수식 앞뒤의 { }는 손으로 입력하는 것이 아니라
<Ctrl + Shift + Enter> 키를 함께 누르면 저절로 생긴다는 것, 잊지 않으셨지요?

2. "3월"의 "동부" 지역 중 실적이 "50 이상"인 경우

여기서부터는 셀 영역에 이름을 정의해 두고 수식에 사용했습니다.
어느 영역에 어떤 이름을 지정하였는지는 워크시트 좌측 상단에 있는
이름 상자(Name Box)에서 확인해 보세요.

월   =Preface!$B$24:$B$53
지역 =Preface!$C$24:$C$53
유형 =Preface!$D$24:$D$53
실적 =Preface!$E$24:$E$53

Excel 2007 이상:

=COUNTIFS(월,"3월",지역,"동부",실적,">=50")

Excel 2007 이전:

=SUMPRODUCT((월="3월")*(지역="동부")*(실적>=50))

배열 수식 사용:

{=SUM((월="3월")*(지역="동부")*(실적>=50))}

결과는 세 수식 모두 2입니다(3월 동부 지역의 실적 99와 51).

엑셀 2007 이전의 경우에는 Sumproduct를 이용하여 해결할 수 있겠군요.

3. "2월"과 "3월"의 자료 건수

Countif 함수 사용:

=COUNTIF(월,"2월")+COUNTIF(월,"3월")

배열 수식 사용:

{=SUM(COUNTIF(월,{"2월","3월"}))}

결과는 두 수식 모두 20입니다.
여기서는 배열 수식을 사용할 때, 2월과 3월을 중괄호 안에 넣어서 인수로 전달 해주는
방법을 사용한 점을 눈여겨 보시면 되겠습니다.

4. 3월 자료 중 서부와 북부 자료 중 실적이 100 이상인 경우

배열 수식 사용:

{=SUM((월="3월")*IF((지역="서부")+(지역="북부"),1)*(실적>=100))}

결과는 2입니다(서부 398, 북부 216).
조건이 복잡하니 수식도 덩달아 길어졌군요.
하지만 And 조건인지 Or 조건인지를 사전에 잘 생각해서 수식으로 바꿔주면 되니까
너무 겁먹지 마시기 바랍니다.^^

자, 또 뭐가 더 있을까요…
나머지는 여러분들이 응용력을 발휘해 보시기 바랍니다.

정리 — 조건별 수식 한눈에 보기

조건	권장 수식
범위 조건(200 이상 300 미만)	=COUNTIFS(범위,">=200",범위,"<300")
여러 열의 And 조건	=COUNTIFS(월,"3월",지역,"동부",실적,">=50")
여러 항목의 합	=COUNTIF(월,"2월")+COUNTIF(월,"3월")
And·Or 복합 조건	배열 수식: 조건식을 곱하고(And) 더한다(Or)

자주 묻는 질문 (FAQ)

마치며

오늘은 여기까지…