최초 작성일: 2013-01-15
최종 수정일: 2026-09-21
조회수: 31 회
작성자: 권현욱 (엑셀러)
강의 제목: 동점자 처리하기

들어가기 전에

오래 전 엑셀 파일로 진행하던 강의를 웹 글로 복원한 것이라, "버튼을 눌러보세요"처럼 엑셀에서 직접 조작하라는 표현이 남아 있을 수 있습니다. 결과는 본문의 그림이나 표로 확인하실 수 있으며, 현재와 맞지 않는 내용은 보완하되 전반적인 스타일은 당시의 갬성(?)을 유지했습니다.

새해가 밝은 지도 보름이 지났습니다.
연초 계획대로 잘 진행되고 있는지 점검해 볼 시간인 것 같습니다.
'의미있는 삶'이란 도대체 무엇일까 목하 고민하며 책을 보던 중 드디어…
"시간을 천천히 흐르게 하는 방법"을 발견(?)했습니다.

그것은 바로…

기억할 만한 일을 자꾸 만들어 내면 됩니다.

학창 시절 및 20대까지는 매일매일이 새로운 일의 연속이었습니다.
졸업, 입학, 미팅, 취직, 첫 사랑, 연애, 결혼 등등…

그러던 것이… 아이를 낳고 생활이 안정되고 나서부터는
비슷비슷하기만 하고
그저 바쁘기만 한 날들이 연속됩니다.

"바쁘기만 하지 기억할 만한 일들이 전혀 없으면 시간은 미친 듯 날아간다"

평소에 하던 반복되는 일들과는 다른 새로운 것을 시도해 보세요.
꼭 크고 거창한 것만 시도할 필요는 없을 듯 합니다.

예전부터 한번 해보고 싶었으나 선뜻 하기 어려웠던 일,
이전과는 다른 맥락에서 바라보고, 의미를 부여할 수 있는 일이면 되겠습니다.

// 질문 하나

안녕하세요. 바쁘신데 문의를 좀 드릴까 합니다.

네이버도 뒤져보고 엑셀러 닷컴도 좀 보고 있긴 한데,
매번 쓰는 게 아니다보니, 그 때마다 임기응변으로 넘어가기도 하고요.
SUMPRODUCT를 써서 해결을 하긴 했는데,
첨부 파일을 급히 만들었는데요. 같은 학과내에서 순위를 보고 싶은데,
총점 동점자가 발생할 경우 국어, 수학 순으로 랭킹을 부여하려고요…

그냥 동점자 순위는 많이 검색되던데, 같은 과 ... 이런 기준을 부여하는 건
안 보여서 부탁드려요.

예제 데이터는 Exceller가 조금 수정 했습니다.
질문하신 분이 사용하신 수식은 이렇습니다.

=SUMPRODUCT(($D$3:$D$17=D3)*($H$3:$H$17>H3))+1

Sumproduct 함수를 사용한 것은 잘 하셨는데 문제는…
같은 모집 단위 내에서 합계 점수가 같은 지원자가 있으면 이렇게
동점자가 마구 생기는데, 이걸 어떻게 처리할 수 없느냐 하는 것입니다.

NO	이름	모집단위	모집단위코드	국어	수학	영어	합계	모집단위내 순위
1	김	영문	14	10	15	10	35	2
2	이	경영	17	10	13	10	33	4
3	박	경영	17	10	12	12	34	2
4	정	사학	11	10	10	13	33	1
5	권	영문	14	20	10	5	35	2
6	조	영문	14	20	5	10	35	2
7	장	사학	11	15	10	8	33	1
8	최	영문	14	15	15	7	37	1
9	장	경영	17	10	11	15	36	1
10	권	경영	17	10	14	10	34	2
11	노	영문	14	9	11	10	30	5
12	박	경영	17	10	10	9	29	6
13	김	사학	11	16	8	6	30	3
14	이	영문	14	2	10	1	13	6
15	주	경영	17	10	10	10	30	5

저자: 권현욱(엑셀러), 아이엑셀러 대표

필자는 Excel 컨설턴트, 작가, 그리고 크리에이터입니다. 현재 Microsoft Excel MVP이며, 『챗GPT+엑셀 업무자동화 정석』을 비롯한 10여 권의 도서를 집필했습니다. Excel 자동화 및 생산성 향상 분야에서 25년 넘는 경력을 보유하고 있습니다.

권현욱(엑셀러) 님의 최신 포스트:

최신 글을 불러오는 중...

엑셀 동점자 처리하기, 같은 그룹 내 순위와 국어·수학·영어 순 비교

Q: 엑셀에서 같은 그룹(학과) 안에서만 순위를 매기려면 어떻게 하나요?

SUMPRODUCT 함수로 같은 그룹이면서 점수가 더 높은 행의 개수를 세고 1을 더합니다. 예제에서는 =SUMPRODUCT(($D$3:$D$17=D3)*($H$3:$H$17>H3))+1처럼 모집단위코드(D열)가 같고 합계(H열)가 더 큰 행의 수에 1을 더해 모집단위 내 순위를 구합니다.

핵심 요약: 동점자 없이 그룹 내 순위 매기기

SUMPRODUCT 함수로 같은 모집단위 안에서의 순위를 구하고, 합계가 같을 때는 국어 → 수학 → 영어 순으로 비교하는 조건을 더해 동점자를 없앱니다.

기본 수식: =SUMPRODUCT(($D$3:$D$17=D3)*($H$3:$H$17>H3))+1은 동점자를 같은 순위로 처리합니다.
비교 순서: 모집단위와 합계 → 같으면 국어 → 같으면 수학 → 같으면 영어 순으로 비교합니다.
And와 Or: 조건식은 * (And)로 연결하고 각 비교 단계는 + (Or)로 합칩니다.
결과: 같은 모집단위 안에서 순위가 겹치는 사람이 한 명도 없게 됩니다.

1. 무엇이 문제일까요?

예제 파일의 Workplace 시트에서 '모집단위내 순위' 열을 살펴보시기 바랍니다.
아래 표에서 노란색으로 표시한 순위가 같은 모집단위 안의 동점자입니다.

예를 들어 영문(모집단위코드 14)의 김, 권, 조는 합계가 모두 35점이라 모두 2위가 되어 있습니다.

2. 동점자 없이 순위 매기기

이번에는 같은 모집단위 내에서는 동점자가 한 사람도 나오지 않는 순위를 살펴보겠습니다.
맨 오른쪽 열이 Exceller가 수정한 순위입니다.

NO	이름	모집단위	모집단위코드	국어	수학	영어	합계	모집단위내 순위	Exceller가 수정한 순위
1	김	영문	14	10	15	10	35	2	4
2	이	경영	17	10	13	10	33	4	4
3	박	경영	17	10	12	12	34	2	3
4	정	사학	11	10	10	13	33	1	2
5	권	영문	14	20	10	5	35	2	2
6	조	영문	14	20	5	10	35	2	3
7	장	사학	11	15	10	8	33	1	1
8	최	영문	14	15	15	7	37	1	1
9	장	경영	17	10	11	15	36	1	1
10	권	경영	17	10	14	10	34	2	2
11	노	영문	14	9	11	10	30	5	5
12	박	경영	17	10	10	9	29	6	6
13	김	사학	11	16	8	6	30	3	3
14	이	영문	14	2	10	1	13	6	6
15	주	경영	17	10	10	10	30	5	5

어떻습니까?
같은 모집단위 내에서는 동점자가 한 사람도 보이지 않지요?

Workplace 시트의 K3 셀에 입력된 수식은 이렇습니다.

=SUMPRODUCT(
    (($D$3:$D$17=D3)*($H$3:$H$17>H3))+
    (($D$3:$D$17=D3)*($H$3:$H$17=H3)*($E$3:$E$17>E3))+
    (($D$3:$D$17=D3)*($H$3:$H$17=H3)*($E$3:$E$17=E3)*($F$3:$F$17>F3))+
    (($D$3:$D$17=D3)*($H$3:$H$17=H3)*($E$3:$E$17=E3)*($F$3:$F$17=F3)*($G$3:$G$17>G3))
)+1

정정: 수식의 셀 주소

원문은 질문자의 수식을 ($D$3:$D$17=E22)*($H$3:$H$17>I22)로 적어 예제 파일과 셀 주소가 맞지 않았습니다. 예제 파일의 I3 셀 수식에 맞춰 D3, H3으로 바로잡았습니다. 또 긴 수식은 줄이 바뀌는 자리에 +가 겹쳐 있던 것을 정리하고 읽기 쉽게 줄바꿈과 들여쓰기를 넣었습니다. 수식을 셀에 입력할 때는 줄바꿈 없이 한 줄로 이어도 결과는 같습니다.

3. 수식의 원리

질문하신 분의 질문 속에 답이 있습니다.

먼저, 모집단위와 합계 점수를 비교하고,
다음으로, 모집단위와 합계 점수가 같은 경우 국어 점수를 비교하고,
그래도 같으면, 국어와 수학, 영어 점수까지 싸그리 비교한다!

이 과정을 엑셀이 알아먹을 수 있도록 표현한 것이 위의 수식입니다.
문제에 어떻게 접근할 것인지만 잘 정리되면 해결은 쉬워집니다.
수식에서 *는 And, +는 Or를 의미한다는 사실을 염두에 두고 보시면
어렵지 않게 이해하시리라 생각합니다.

💡 기억해 둘 말

"잘 정리된 문제는 이미 절반은 해결된 문제이다"
라는 말은 그런 의미에서 진리입니다.

참고: Excel 2007 이상에서는

동점자를 같은 순위로 두는 기본 순위(첫 번째 수식)는 Excel 2007 이상에서 =COUNTIFS($D$3:$D$17,D3,$H$3:$H$17,">"&H3)+1로도 구할 수 있습니다. 여러 기준으로 동점자를 가리는 수식은 이 글처럼 SUMPRODUCT를 쓰는 편이 간단합니다.

정리 — 순위 수식 한눈에 보기

구분	수식의 뜻
기본 순위	같은 모집단위이면서 합계가 더 높은 사람 수 + 1 (동점자는 같은 순위)
1차 비교	모집단위와 합계 비교
2차 비교	합계가 같으면 국어 비교
3차, 4차 비교	국어까지 같으면 수학, 그래도 같으면 영어 비교

자주 묻는 질문 (FAQ)

Q1. 엑셀에서 같은 그룹(학과) 안에서만 순위를 매기려면 어떻게 하나요?

SUMPRODUCT 함수로 같은 그룹이면서 점수가 더 높은 행의 개수를 세고 1을 더합니다. 예제에서는 =SUMPRODUCT(($D$3:$D$17=D3)*($H$3:$H$17>H3))+1처럼 모집단위코드(D열)가 같고 합계(H열)가 더 큰 행의 수에 1을 더해 모집단위 내 순위를 구합니다.

Q2. 동점자가 있을 때 국어, 수학, 영어 순으로 순위를 가리려면 어떻게 하나요?

비교 기준마다 조건식을 만들어 더합니다. 먼저 합계가 더 높은 경우, 합계가 같으면서 국어가 더 높은 경우, 합계와 국어가 같으면서 수학이 더 높은 경우, 여기까지 모두 같으면서 영어가 더 높은 경우를 각각 곱셈(And)으로 연결한 뒤 이들을 덧셈(Or)으로 합쳐 SUMPRODUCT 안에 넣고 마지막에 1을 더합니다.