- 최초 작성일: 2007-03-20
- 최종 수정일: 2026-09-26
- 조회수: 13 회
- 작성자: 권현욱 (엑셀러)
- 강의 제목: COUNTIFS와 SUMIFS로 여러 조건 계산하기
들어가기 전에
오래 전 엑셀 파일로 진행하던 강의를 웹 글로 복원한 것이라, "버튼을 눌러보세요"처럼 엑셀에서 직접 조작하라는 표현이 남아 있을 수 있습니다. 결과는 본문의 그림이나 표로 확인하실 수 있으며, 현재와 맞지 않는 내용은 보완하되 전반적인 스타일은 당시의 갬성(?)을 유지했습니다.
Excel 2007에서 새로 추가된 COUNTIFS와 SUMIFS 함수를 사용하면 여러 조건을 만족하는 데이터의 개수와 합계를 간단하게 계산할 수 있습니다.
- 최신 글을 불러오는 중...
COUNTIFS와 SUMIFS로 여러 조건 계산하기
핵심 요약: COUNTIFS·SUMIFS
여러 조건을 만족하는 데이터의 개수와 합계를 COUNTIFS와 SUMIFS로 직접 계산할 수 있습니다.
- COUNTIFS는 여러 조건을 만족하는 셀의 개수를 구합니다.
- SUMIFS는 여러 조건을 만족하는 값의 합계를 구합니다.
- Excel 2003 이하에서는 SUMPRODUCT나 배열 수식으로 같은 문제를 해결할 수 있습니다.
오래간만에 인사를 드리는군요. Excel 2007 버전을 사용하는 분들이 조금씩 늘어나고 있는 것 같습니다. 새로운 버전에서 강화된 기능을 하나씩 살펴보겠습니다.
오늘은 Excel 2007에서 새로 추가된 함수 가운데 COUNTIFS와 SUMIFS를 알아봅니다.
예제 데이터
다음과 같은 직원 데이터가 있습니다.
| 이름 | 부서 | 직급 | 성별 | 학력 | 연봉 |
|---|---|---|---|---|---|
| 이순신 | 총무부 | 사원 | 남 | 고졸 | 22,000,000 |
| 김유신 | 영업부 | 부장 | 남 | 대졸 | 55,000,000 |
| 김춘추 | 홍보부 | 차장 | 남 | 대졸 | 48,000,000 |
| 조햇님 | 경리부 | 대리 | 여 | 고졸 | 30,000,000 |
| 장진 | 영업부 | 전무 | 남 | 고졸 | 100,000,000 |
| 박종태 | 기획부 | 상무 | 남 | 대학원졸 | 80,000,000 |
| 윤원기 | 총무부 | 사원 | 남 | 대졸 | 17,500,000 |
| 권현욱 | 경리부 | 대리 | 남 | 대졸 | 40,000,000 |
| 주정민 | 영업부 | 과장 | 여 | 대졸 | 50,000,000 |
| 박아름 | 영업부 | 주임 | 여 | 고졸 | 18,500,000 |
| 김남주 | 인사부 | 사원 | 여 | 고졸 | 14,000,000 |
| 박상진 | 인사부 | 이사 | 남 | 대졸 | 70,000,000 |
| 이진숙 | 기획부 | 이사 | 여 | 대졸 | 75,000,000 |
| 최동진 | 총무부 | 과장 | 여 | 대졸 | 45,000,000 |
| 권예지 | 총무부 | 대리 | 여 | 대학원졸 | 20,000,000 |
여기서 '남자'이면서 '대졸' 직원의 수를 구하거나, '총무부' 소속이면서 '남자'이면서 '대졸' 직원의 연봉 총액을 구하려면 어떻게 해야 할까요?
방법 1: SUMPRODUCT 함수 사용
① 남자이면서 대졸 직원의 수
=SUMPRODUCT((E29:E43="남")*(F29:F43="대졸"))
② 총무부 소속의 남자이면서 대졸 직원의 연봉 총액
=SUMPRODUCT((C29:C43="총무부")*(E29:E43="남")*(F29:F43="대졸")*(G29:G43))방법 2: 배열 수식 사용
① {=SUM((E29:E43="남")*(F29:F43="대졸"))}
② {=SUM((C29:C43="총무부")*(E29:E43="남")*(F29:F43="대졸")*(G29:G43))}수식 앞뒤의 중괄호는 Ctrl + Shift + Enter 키를 함께 누르면 자동으로 생깁니다.
방법 3: COUNTIFS와 SUMIFS 함수 사용
① =COUNTIFS(E29:E43,"남",F29:F43,"대졸")
② =SUMIFS(G29:G43,C29:C43,"총무부",E29:E43,"남",F29:F43,"대졸")COUNTIFS와 SUMIFS를 사용하면 다중 조건의 개수나 합을 보다 직접적으로 표현할 수 있습니다.
사용 형식
COUNTIFS(range1, criteria1, range2, criteria2...)
SUMIFS(sum_range, range1, criteria1, range2, criteria2...)| 함수 | 인수 | 설명 |
|---|---|---|
| COUNTIFS | range1, range2… | 관련 조건을 평가할 범위 |
| COUNTIFS | criteria1, criteria2… | 개수를 계산할 조건 |
| SUMIFS | sum_range | 합계를 구할 범위 |
| SUMIFS | range1, range2… | 관련 조건을 평가할 범위 |
| SUMIFS | criteria1, criteria2… | 합계를 계산할 조건 |
COUNTIFS와 SUMIFS는 Excel 2007에서 추가된 함수이므로 그 이전 버전에서는 #NAME? 오류가 발생할 수 있습니다.
정리
여러 조건을 만족하는 데이터의 개수나 합계를 구할 때 COUNTIFS와 SUMIFS를 사용하면 이전 버전에서 SUMPRODUCT나 배열 수식으로 처리하던 작업을 보다 간단한 형태로 작성할 수 있습니다.
