오늘 강좌도 <월간 PC라인> 9월호에 기고한 내용 중 일부를 편집한 것입니다. 전개 방식이 다소 드라이하고, 반말로 진행하더라도 이해해 주시기 바래요. ~~

Sub CompareRadar()

    Dim rngSource As Range
    Dim i As Integer
    Dim strSheetName As String
    '등장인물들과 배역을 설정합니다.

    Set rngSource = Range("Source")
    Application.ScreenUpdating = False
    On Error Resume Next

    ActiveSheet.ChartObjects.Delete
    '현재 시트에 이미 만들어진 차트가 있다면 지웁니다. 만약 차트가 없다면 오류가 발생
    '하므로 앞에서 On Error Resume Next 구문을 추가하였습니다.

    strSheetName = ActiveSheet.Name

    For i = 1 To rngSource.Columns.Count - 1
    '몇 명의 전투력을 비교할 것인지 순환횟수를 지정합니다.
        Charts.Add

        With ActiveChart
            .ChartType = xlRadarFilled
            .SetSourceData Worksheets(strSheetName). _
                Range(rngSource.Columns(1).Address _
                & "," & rngSource.Columns(i + 1).Address)
            .Location xlLocationAsObject, strSheetName
            '차트의 종류, 원본 데이터, 차트를 이동할 위치 등을 지정합니다.

        End With

        With ActiveSheet.ChartObjects(i)
        '차트를 삽입할 위치를 지정합니다. 변수 i의 값을 통해 각 차트별로 위치를 다르게
        '지정해 줍니다.
            .Top = Range("Chart" & i).Top
            .Left = Range("Chart" & i).Left
            .Width = Range("Chart" & i).MergeArea.Width
            .Height = Range("Chart" & i).MergeArea.Height
        End With

        With ActiveChart
        '삽입된 차트의 각종 서식을 변경(또는 지정)합니다. 생소한 오브젝트나 메서드,
        '프로퍼티에 대해서는 해당 위치에서 <F1> 키를 누르면 자세한 도움말이 나오므로
        '직접 확인하도록 하세요.

            .SeriesCollection(1).Fill.OneColorGradient _
                Style:=msoGradientHorizontal, _
                Variant:=1, Degree:=0.9
            .SeriesCollection(1).ApplyDataLabels
            .Legend.Delete
            .ChartStyle = 30
            .SetElement (msoElementChartTitleCenteredOverlay)

            With .SeriesCollection(1).DataLabels
                .Font.ColorIndex = 3
                .Font.Bold = True
                .Interior.ColorIndex = 6
            End With

            With .ChartTitle
                .Font.Size = 12
                .Left = 0
                .Top = 0
            End With

            With .Axes(xlValue)
                .MajorGridlines.Border.LineStyle = xlDot
                .MaximumScale = 10
            End With
        End With

    Next i

    rngSource.Cells(1).Select
    Application.ScreenUpdating = True
    MsgBox "전투력 비교시트 작성이 완료되었습니다!", , "아이엑셀러 닷컴//Exceller"

End Sub